27
Fri, Dec
0 New Articles
  1. You are here:  
  2. Home
  3. Programming
  4. RPG
  5. Create an Auto-Extend User Space

Create an Auto-Extend User Space

RPG
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

Editor's Note: This article is an excerpt from RPG TnT: 101 Dynamite Tips 'n Techniques with RPG IV.

 

The User Space is an interesting object. User Spaces have been around on this architecture for nearly 20 years, and yet many people still don't know how to create them or why they would use them. In fact, the underlying object on which User Spaces are based was the first object created for this architecture back in the mid-1970s.

 

The reason most people don't know how to create user space objects is that OS/400 never shipped with a CL command to create this type of object. There is a DLTUSRSPC command, but no CRTUSRSPC command. Some people have created their own userwritten CRTUSRSPC command (one is included in RPG xTools).

 

The User Space is becoming more popular lately because RPG IV allows you to use it for dynamic memory allocation, which in turn allows you to create dynamically sized arrays, data structure arrays, and dynamic memory allocations without actually using the precious (and expensive) system RAM or main storage, as we like to call it.

 

User Spaces are arguably the most optimized objects on the system. They have the ability to automatically grow from a few bytes in length up to 16MB, which is their limit. This allows you to store information in a user space and not worry about the size of the user space—it automatically (and seemingly magically) grows as necessary.

 

To create a user space, the QUSCRTUS API is used. It creates a user space and sets the User Space's default properties or attributes. The following is the prototype for QUSCRTUS:

 

Prototype for QUSCRTUS (Create User Space) API

D QusCrtUsrSpace  PR                  extPgm('QUSCRTUS')

D  UsrSpace                     20A   Const

D  ExtAttr                      10A   Const

D  nSize                        10I 0 Const

D  InitValue                    1A    Const

D  PubAuth                      10A   Const

D  szTextDesc                   50A   Const

D  Replace                      10A   Const

D  api_error                          LikeDS(QUSEC_T)

D                                     OPTIONS(*VARSIZE)

D  bSysDomain                   10A   Const OPTIONS(*NOPASS)

 

Using this API to create a user space requires several parameters, but once a prototype is created, specifying values for those parameters is relatively easy:

 

D mySpaceName       DS                Qualified

D  UsrSpace                     10A   Inz('MYUSRSPC')

D  LibName                      10A   Inz('QGPL')

 

 /free

     CallP(e)  QusCrtUsrSpace(mySpaceName:

                    'MYSTUFF' : 6000 : X'00' :

                    '*ALL' : 'Bob''s Stuff' :

                    '*YES' : apiErrorDS);

 /end-free

 

In this example, a user space named MYUSRSPC is created in the QGPL library. The extended object attribute is 'MYSTUFF'. This attribute is visible using the DSPOBJD CL command and is stored just like the RPGLE attribute of an RPG IV program or the PF attribute of a database file.

 

The user space's initial length is set to 6,000 bytes and is initialized to X'00'. Any character can be used to initialize the user space. Most programmers tend to use blanks (X'40') but hex zeros (X'00') are much more efficient than any other character, including blanks. The object's text description is set to 'Bob's Stuff', and the Replace object parameter is '*YES'. Specifying '*YES' for the Replace parameter is just like specifying REPLACE(*YES) when (re)compiling a program.

 

If the user space needs to be auto-extending, then the QUSCUSAT (Change User Space Attributes) API is to be called. For some reason, this attribute can't be set when initially creating a user space.

 

The prototype for the QUSCUSAT API is as follows:

 

Change User Space Attributes (QUSCUSAT) API Prototype

D QusChgUsrSpaceAttr...

D                 PR                  extPgm('QUSCUSAT')

D  RtnLibName                   10A

D  UsrSpace                     20A   Const

D  USAttr                       64A   OPTIONS(*VARSIZE)

D  api_error                          LikeDS(QUSEC_T)

D                                     OPTIONS(*VARSIZE)

 

This API can change several attributes of a user space simultaneously or individually. Each attribute is specified in a data structure. For example, to set the Auto Extend attribute, the following data structure is used:

 

D usAutoExt         DS                Qualified

D  nRecdCount                   10I 0 Inz(1)

D  nAttrKey                     10I 0 Inz(3)

D  nAttrLen                     10I 0 Inz(1)

D  bExtend                      1A Inz('1')

 

The first subfield, nRecdCount, is the number of User Space Attribute "records" you have included in this data structure. To change the Auto-Extend attribute, we only need one record.

 

The second subfield, nAttrKey, contains the attribute key for the attribute being changed. To change the Auto Extend attribute, a key value of 3 is required.

The third subfield, nAttrLen, indicates the length of the value specified for the attribute being changed. The user space Auto Extend attribute is 1 byte long, so this field is initialized to 1.

The fourth subfield is the user space attribute value being applied. For Auto Extend, this field is a 1-byte character field. Setting this field to '1' enables the user space's Auto Extend attribute. A value of '0' disables the Auto Extend attribute.

To change the size of the user space, the following data structure is used:

 

D usSize            DS                Qualified

D  nRecdCount                   10I 0 Inz(1)

D  nAttrKey                     10I 0 Inz(1)

D  nAttrLen                     10I 0 Inz(4)

D  nNewSize                     10I 0 Inz(12000)

 

The second subfield, nAttrKey is set to 1 (the key used to indicate User Space size), and the fourth field is changed to an integer (10i0). The new size of the user space must be specified in the nNewSize subfield.

 

All user space objects are created with a fixed length. To set the auto-extend attribute, the QUSCUSAT APIs must be called after they are created, as follows:

 

Create User Space and Change Attribute to Auto-Extend

D userSpaceAttr     DS                Qualified

D  nRecdCount                   10I 0 Inz(1)

D  nAttrKey                     10I 0 Inz(3)

D  nAttrLen                     10I 0 Inz(1)

D  bExtend                       1A   Inz('1')

 

D  apiErrorDS       DS                LikeDS(QUSEC) Inz

D  rtnLib           S          10A

 

 /free

     QusCrtUsrSpace('MYUSRSPC QGPL':

                    'MYSTUFF' : 6000 : X'00' :

                    '*ALL' : 'Bob''s Stuff' :

                    '*YES' : apiErrorDS);

 

     QusChgUsrSpaceAttr(rtnLib : 'MYUSRSPC QGPL' :

                         userSpaceAttr : QUSEC);

 /end-free

 

In this example, the name of the user space is passed on the second parameter and followed by the USERSPACEATTR data structure. This data structure contains the elements necessary to set on the user space's auto-extend attribute, as follows:

  • nRecdCount — Number of User Space Attributes being modified.
  • nAttrKey — Identifier that indicates which key is being modified. To change the autoextend attribute, the key of 3 is needed.
  • nAttrLen — Length of the data being used for the attribute's new value. Since autoextend is a yes/no value (i.e., a logical '1' or '0'), the length is set to 1.
  • bExtend — Indicates if the auto-extend attribute is being turned on or turned off. A value of '1' means turn on auto-extend; '0' means turn off auto-extend.

Changing Multiple User Space Attributes

It is relatively easy to set up a data structure for each of the user space attributes and then a master data structure with nested data structures. This allows you to change any of the user space attributes as follows:

 

D newAttr           DS                Qualified

D  attrCount                    10I 0 Inz(3)

D  size                               LikeDS(QUSKeySize_T) inz(*LIKEDS)

D  initValue                          LikeDS(QUSKeyInit_T) inz(*LIKEDS)

D  autoExt                            LikeDS(QUSKeyAuto_T) inz(*LIKEDS)

 

The data structure NEWATTR contains a subfield named ATTRCOUNT that identifies the number of user space attributes being changed. This value varies based on the nested data structures being specified. In the example above, three (3) attributes are being changed: the size, initial value, and the auto-extend attribute.

 

The SIZE, INITVALUE, and AUTOEXT subfields are nested data structures—that is, they are qualified data structures inside the NEWATTR data structure. If you want to modify only the auto-extend attribute of the user space, only the AUTOEXT subfield should be specified:

 

D newAttr           DS                Qualified

D  attrCount                    10I 0 Inz(1)

D  autoExt                            LikeDS(QUSKeyAuto_T) inz(*LIKEDS)

 

Note that the ATTRCOUNT subfield is now set to 1 instead of 3, and only AUTOEXT is specified.

 

The nested subfields are based on data structure templates that I created. They are defined as follows:

 

User Space Attribute Data Structure Templates

D QUSKeySize_T      DS                Qualified

D  keyID                        10I 0 Inz(1)

D  len                          10I 0 Inz(%size(QUSKeySize_T.value))

D  value                        10I 0 Inz

 

D QUSKeyInit_T      DS                Qualified

D  keyID                        10I 0 Inz(2)

D  len                          10I 0 Inz(%size(QUSKeyInit_T.value))

D  value                         1A   Inz(X'00')

 

D QUSKeyAuto_T      DS                Qualified

D  keyID                        10I 0 Inz(3)

D  len                          10I 0 Inz(%size(QUSKeyAuto_T.value))

D  value                         1A   Inz('1')

 

To set the auto-extend attribute, declare the NEWATTR data structure as previously illustrated and then set the VALUE subfield of the AUTOEXT nested structure:

 

 /free

       newAttr.autoExt.value = '1';

 

       qusChgUserSpaceAttr(rtnLib : 'MYUSRSPC QGPL':

                          newAttr : apiError);

 /end-free

 

Changing the initial value and the auto-extend attribute simultaneously is just as easy:

 

D newAttr           DS                Qualified

D  attrCount                    10I 0 Inz(2)

D  autoExt                            LikeDS(QUSKeyAuto_T) inz(*LIKEDS)

D  initValue                          LikeDS(QUSKeyInit_T) inz(*LIKEDS)

 

 /free

       newAttr.autoExt.value = '1';

       newAttr.initValue.value = X'00';

 

       qusChgUserSpaceAttr(rtnLib : 'MYUSRSPC QGPL':

                          newAttr : apiError);

 /end-free

 

Editor's Note: This article is an excerpt from RPG TnT: 101 Dynamite Tips 'n Techniques with RPG IV.

as/400, os/400, iseries, system i, i5/os, ibm i, power systems, 6.1, 7.1, V7, V6R1

BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

$

Book Reviews

Resource Center

  • SB Profound WC 5536 Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. You can find Part 1 here. In Part 2 of our free Node.js Webinar Series, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Brian will briefly discuss the different tools available, and demonstrate his preferred setup for Node development on IBM i or any platform. Attend this webinar to learn:

  • SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.

  • SB HelpSystems ROBOT Generic IBM announced the E1080 servers using the latest Power10 processor in September 2021. The most powerful processor from IBM to date, Power10 is designed to handle the demands of doing business in today’s high-tech atmosphere, including running cloud applications, supporting big data, and managing AI workloads. But what does Power10 mean for your data center? In this recorded webinar, IBMers Dan Sundt and Dylan Boday join IBM Power Champion Tom Huntington for a discussion on why Power10 technology is the right strategic investment if you run IBM i, AIX, or Linux. In this action-packed hour, Tom will share trends from the IBM i and AIX user communities while Dan and Dylan dive into the tech specs for key hardware, including:

  • Magic MarkTRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now!  Request Now.

  • SB HelpSystems ROBOT GenericForms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.

  • SB HelpSystems ROBOT GenericIT security is a top priority for businesses around the world, but most IBM i pros don’t know where to begin—and most cybersecurity experts don’t know IBM i. In this session, Robin Tatam explores the business impact of lax IBM i security, the top vulnerabilities putting IBM i at risk, and the steps you can take to protect your organization. If you’re looking to avoid unexpected downtime or corrupted data, you don’t want to miss this session.

  • SB HelpSystems ROBOT GenericCan you trust all of your users all of the time? A typical end user receives 16 malicious emails each month, but only 17 percent of these phishing campaigns are reported to IT. Once an attack is underway, most organizations won’t discover the breach until six months later. A staggering amount of damage can occur in that time. Despite these risks, 93 percent of organizations are leaving their IBM i systems vulnerable to cybercrime. In this on-demand webinar, IBM i security experts Robin Tatam and Sandi Moore will reveal:

  • FORTRA Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:

  • FORTRAManaging messages on your IBM i can be more than a full-time job if you have to do it manually. Messages need a response and resources must be monitored—often over multiple systems and across platforms. How can you be sure you won’t miss important system events? Automate your message center with the Robot Message Management Solution. Key features include:

  • FORTRAThe thought of printing, distributing, and storing iSeries reports manually may reduce you to tears. Paper and labor costs associated with report generation can spiral out of control. Mountains of paper threaten to swamp your files. Robot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing. Manage your reports with the Robot Report Management Solution. Key features include:

  • FORTRAFor over 30 years, Robot has been a leader in systems management for IBM i. With batch job creation and scheduling at its core, the Robot Job Scheduling Solution reduces the opportunity for human error and helps you maintain service levels, automating even the biggest, most complex runbooks. Manage your job schedule with the Robot Job Scheduling Solution. Key features include:

  • LANSA Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.

  • LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed. Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

  • LANSASupply Chain is becoming increasingly complex and unpredictable. From raw materials for manufacturing to food supply chains, the journey from source to production to delivery to consumers is marred with inefficiencies, manual processes, shortages, recalls, counterfeits, and scandals. In this webinar, we discuss how:

  • The MC Resource Centers bring you the widest selection of white papers, trial software, and on-demand webcasts for you to choose from. >> Review the list of White Papers, Trial Software or On-Demand Webcast at the MC Press Resource Center. >> Add the items to yru Cart and complet he checkout process and submit

  • Profound Logic Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.

  • SB Profound WC 5536Join us for this hour-long webcast that will explore:

  • Fortra IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn: