12
Tue, Nov
6 New Articles
  1. You are here:  
  2. Home
  3. Programming
  4. RPG
  5. Tips and Techniques: Date Values

Tips and Techniques: Date Values

RPG
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

One of the cool things about CL (even though I rarely, if ever, use it anymore) is that it is extendable. But one thing it does badly is date manipulation. Effectively, it only handles decimal fields that contain something similar to a date. It is up to the programmer to come up with creative techniques to manipulate date values.

One of the things RPG IV does exceptionally well is date arithmetic. So why not leverage that capability by creating a new CL command that adds a duration to a date value from within CL?

The first thing you have to do is decide in what format the input and output date values will be specified. Since CL uses the job date format extensively, that is the format I've selected for this example command.

The Add Date Duration (ADDDUR) command adds the indicated number of dates to the base date and returns the resulting date to the CL variable specified on the RTNDATE parameter.

You declare a six-digit character variable in CL and populate it with the starting date for the command, calling ADDDUR with the duration you want to add to that date. The duration is added and the resulting date is returned in *JOBRUN format, which is the same as the job date format.

The following is the source for the ADDDUR CL command.

ADDDUR:     CMD        PROMPT('Add a duration to a date')

             /* ------------------------------------------- */
             /*  Command processing program is: ADDDUR      */
             /* ------------------------------------------- */
             /*   COMPILE WITH: ALLOW(*IPGM *BPGM)          */
             /* ------------------------------------------- */
             /* ----------------------------------------------- */
             /*   DATE(*TODAY | *SYSDATE) are the equivalent.   */
             /*   DATE(*JOBDATE | *JOBRUN) are the equivalent.  */
             /*   DATE(*SBMJOB) is the date the job was         */
             /*           submitted. (aka, submitted-on date).  */
             /*   All other values are based on the system      */
             /*   date not the job-start date.                  */
             /* ----------------------------------------------- */

             PARM       KWD(DATE) TYPE(*DATE) DFT(*JOBDATE) +
                          SPCVAL((*TODAY 000000) (*SYSDATE 000000) +
                          (*TOMORROW 000001) (*YESTERDAY 000002) +
                          (*JOBDATE 000003) (*JOBRUN 000003) +
                          (*SBMDATE 000004)) PROMPT('Base Date')
             PARM       KWD(DURATION) TYPE(*INT4) DFT(1) +
                          PROMPT('Number of days to add')
          /* Returned date is always in Job Date Format  */
             PARM       KWD(RTNDATE) TYPE(*CHAR) LEN(6) RTNVAL(*YES) +
                          CHOICE('Rtn Format: Job Date Format') +
                          PROMPT('CL var.  Return Date')

ADDDUR Parameters

DATE is the input date value. This value must be specified in job date format if specified in a CL variable. If a date literal is specified, it may be in MMDDYYYY, MMDDYY, or CYYMMDD format. It accepts dates returned in job date format from the RTVJOBA command.

In addition to a date value, the following special values may be specified:

  • *TODAY--Today's date, based on the system date (not the job date)
  • *SYSDATE--Same as *TODAY, but can be used to be more clear about the date
  • *JOBDATE or *JOBRUN--The job date
  • *SBMDATE--The date the job was submitted to the job queue
  • *YESTERDAY--The date prior to the current system date
  • *TOMORROW--The date following the current system date

DURATION is the number of days you want to add to the date specified on the DATE parameter. The duration may be any number--negative, zero, or positive.

RTNDATE specifies a six-position character CL variable that will receive the returned date value in job date format.

To add seven days to today's system date, do the following:

ADDDUR DATE(*TODAY) DURATION(7) RTNDATE(&NEXTWEEK)

To retrieve tomorrow's date, do this:

ADDDUR DATE(*TOMORROW) DURATION(0) RTNDATE(&TOMORROW)

The following RPG IV program, ADDDUR, is the command processing program for the ADDDUR command. It performs the date arithmetic. Specify this program when compiling the ADDDUR command.

     H OPTION(*NODEBUGIO:*SRCSTMT)
     H DFTACTGRP(*NO)

      ** © 2005 by Robert Cozzi, Jr. 
      **   All rights reserved.

     D ADDDUR          PR
     D inDate                         7A    Const
     D nDur                           5I 0  Const
     D rtnDate                        6A

     D ADDDUR          PI
     D inDate                         7A   Const
     D nDur                           5I 0 Const
     D rtnDate                        6A

     D Today           S               D   Inz(*SYS)
     D JOBDate         S               D   Inz(*JOB)
     D Job             S             26A
     D IntrnlJobID     S             16A
     D SBMDate         S              8A

      /INCLUDE QSYSINC/QRPGLESRC,QUSRJOBI
      /INCLUDE QSYSINC/QRPGLESRC,QUSEC

     D PSDS           SDS
     D  JobName                      10A   Overlay(PSDS:244)
     D  JobUser                      10A   Overlay(PSDS:254)
     D  JobNbr                        6A   Overlay(PSDS:264)

     D CvtDate         PR                  ExtPgm('QWCCVTDT')
     D  inFmt                        10A   Const OPTIONS(*VARSIZE)
     D  inDate                       64A   Const OPTIONS(*VARSIZE)
     D  outFmt                       10A   Const OPTIONS(*VARSIZE)
     D  outDate                      64A         OPTIONS(*VARSIZE)
     D  api_error                          Like(QUSEC) OPTIONS(*VARSIZE)

     D RtvJobA         PR                  ExtPgm('QUSRJOBI')
     D  rtnBuffer                 32767A   OPTIONS(*VARSIZE)
     D  nRtnBufLen                   10I 0 Const
     D  FmtName                       8A   Const
     D  Job                          26A   Const
     D  IntrnlJobID                  16A   Const
     D  api_error                          Like(QUSEC) OPTIONS(*VARSIZE)

     D newDate         S               D
     D baseDate        S               D

     C                   eval      *INLR = *ON

     C                   SELECT
      **  Today?
     C                   When      inDate  = '0000000'
     C                   MOVE      Today         BaseDate
      **  Tomorrow?
     C                   When      inDate = '0010000'
     C     Today         AddDur    1:*DAYS       BaseDate
      **  Yesterday?
     C                   When      inDate = '0020000'
     C     Today         SubDur    1:*DAYS       BaseDate
      **  Job date?
     C                   When      inDate = '0030000'
     C                   MOVE      JOBDATE       BaseDate
      **  Submitted-on Date?  *SBMDATE
     C                   When      inDate = '0040000'
     C                   eval      Job = JobName + JobUser + JobNbr
     C                   clear                   QUSEC
     C                   clear                   QUSI030000
     C                   eval      QUSBPRV = %size(QUSEC)
     C                   Callp     RtvJobA(QUSI030000:%size(QUSI030000) :
     C                                     'JOBI0300' : JOB : IntrnlJobID :
     C                                      QUSEC)
     C                   if        QUSBAVL > 0  or QUSDPOJ = *BLANKS
     C                   Move      JobDate       BaseDate
     C                   else
     C                   eval      SbmDate = QUSDPOJ
     C                   callp     CvtDate('*DTS':QUSDPOJ:'*YYMD':
     C                                      SbmDate : QUSEC ) 
     C     *ISO0         MOVE      SbmDate       BaseDate
     C                   endif
      **  User-specified date
     C                   OTHER
     C     *CYMD0        TEST(DE)                inDate
     C                   if        %Error
     C                   move      today         baseDate
     C                   return
     C                   endif
     C     *CYMD0        move      InDate        baseDate
     C                   endSL

     C                   TEST(E)                 baseDate
     C                   if        %Error
     C                   eval      rtnDate = ' '
     C                   return
     C                   endif

     C     baseDate      AddDur    nDur:*DAYS    newDate
     C     *JOBRUN0      MOVE      newDate       rtnDate

     C                   return

Example of Using ADDDUR

DCL        VAR(&MYDATE) TYPE(*CHAR) LEN(6) 
DCL        VAR(&TOMORROW)  TYPE(*CHAR) LEN(6) 
RTVJOBA    DATE(&MYDATE) 
ADDDUR     DATE(&MYDATE) DURATION(1) RTNDATE(&TOMORROW) 

In this example, the job's date is retrieved into a six-position character variable named &MYDATE. The RTVJOBA command is used to retrieve the date. RTVJOBA always returns the job date as a character value in the job date format.

Then, the ADDDUR command is called to add one day to the job date. The &MYDATE variable contains the job date from the prior RTVJOBA command. The DURATION parameter indicates that one day is added to the value in &MYDATE, and the new date is returned into the &TOMORROW variable, again in job date format.

ADDDUR helps with one of the most difficult issues with respect to CL: date arithmetic. The results can be used in OPNQRYF, embedded SQL (if available), and user interfaces (display files).

The source code for this article and many other RPG tools is available for free download at the RPGIV.com Web site. Click on the free RPG IV downloads link.

Bob Cozzi is a programmer/consultant, writer/author, and software developer. His popular RPG xTools add-on subprocedure library for RPG IV is fast becoming a standard with RPG developers. His book The Modern RPG Language has been the most widely used RPG programming book for more than a decade. He, along with others, speaks at and produces the highly popular RPG World conference for RPG programmers.

BOB COZZI

Bob Cozzi is a programmer/consultant, writer/author, and software developer. His popular RPG xTools add-on subprocedure library for RPG IV is fast becoming a standard with RPG developers. His book The Modern RPG Language has been the most widely used RPG programming book for more than a decade. He, along with others, speaks at and produces the highly popular RPG World conference for RPG programmers.

MC Press books written by Robert Cozzi available now on the MC Press Bookstore.

RPG TnT RPG TnT
Get this jam-packed resource of quick, easy-to-implement RPG tips!
List Price $65.00

Now On Sale

The Modern RPG IV Language The Modern RPG IV Language
 Cozzi on everything RPG! What more could you want?
List Price $99.95

Now On Sale
BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

$

Book Reviews

Resource Center

  • SB Profound WC 5536 Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. You can find Part 1 here. In Part 2 of our free Node.js Webinar Series, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Brian will briefly discuss the different tools available, and demonstrate his preferred setup for Node development on IBM i or any platform. Attend this webinar to learn:

  • SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.

  • SB HelpSystems ROBOT Generic IBM announced the E1080 servers using the latest Power10 processor in September 2021. The most powerful processor from IBM to date, Power10 is designed to handle the demands of doing business in today’s high-tech atmosphere, including running cloud applications, supporting big data, and managing AI workloads. But what does Power10 mean for your data center? In this recorded webinar, IBMers Dan Sundt and Dylan Boday join IBM Power Champion Tom Huntington for a discussion on why Power10 technology is the right strategic investment if you run IBM i, AIX, or Linux. In this action-packed hour, Tom will share trends from the IBM i and AIX user communities while Dan and Dylan dive into the tech specs for key hardware, including:

  • Magic MarkTRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now!  Request Now.

  • SB HelpSystems ROBOT GenericForms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.

  • SB HelpSystems ROBOT GenericIT security is a top priority for businesses around the world, but most IBM i pros don’t know where to begin—and most cybersecurity experts don’t know IBM i. In this session, Robin Tatam explores the business impact of lax IBM i security, the top vulnerabilities putting IBM i at risk, and the steps you can take to protect your organization. If you’re looking to avoid unexpected downtime or corrupted data, you don’t want to miss this session.

  • SB HelpSystems ROBOT GenericCan you trust all of your users all of the time? A typical end user receives 16 malicious emails each month, but only 17 percent of these phishing campaigns are reported to IT. Once an attack is underway, most organizations won’t discover the breach until six months later. A staggering amount of damage can occur in that time. Despite these risks, 93 percent of organizations are leaving their IBM i systems vulnerable to cybercrime. In this on-demand webinar, IBM i security experts Robin Tatam and Sandi Moore will reveal:

  • FORTRA Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:

  • FORTRAManaging messages on your IBM i can be more than a full-time job if you have to do it manually. Messages need a response and resources must be monitored—often over multiple systems and across platforms. How can you be sure you won’t miss important system events? Automate your message center with the Robot Message Management Solution. Key features include:

  • FORTRAThe thought of printing, distributing, and storing iSeries reports manually may reduce you to tears. Paper and labor costs associated with report generation can spiral out of control. Mountains of paper threaten to swamp your files. Robot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing. Manage your reports with the Robot Report Management Solution. Key features include:

  • FORTRAFor over 30 years, Robot has been a leader in systems management for IBM i. With batch job creation and scheduling at its core, the Robot Job Scheduling Solution reduces the opportunity for human error and helps you maintain service levels, automating even the biggest, most complex runbooks. Manage your job schedule with the Robot Job Scheduling Solution. Key features include:

  • LANSA Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.

  • LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed. Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

  • LANSASupply Chain is becoming increasingly complex and unpredictable. From raw materials for manufacturing to food supply chains, the journey from source to production to delivery to consumers is marred with inefficiencies, manual processes, shortages, recalls, counterfeits, and scandals. In this webinar, we discuss how:

  • The MC Resource Centers bring you the widest selection of white papers, trial software, and on-demand webcasts for you to choose from. >> Review the list of White Papers, Trial Software or On-Demand Webcast at the MC Press Resource Center. >> Add the items to yru Cart and complet he checkout process and submit

  • Profound Logic Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.

  • SB Profound WC 5536Join us for this hour-long webcast that will explore:

  • Fortra IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn: