Some of the APIs we use, such as QUSLOBJ (List Object Information), create a list of object names and their attributes. In that list, the object creation timestamp (subfield QUSCDT00) and last changed timestamp (subfield QUSCDT01) are generated. These fields are defined as 8-byte character fields and referred to as "timestamps." But they are not formatted in what we traditionally think of as a timestamp or even a date or time format. Instead, they are in what is sometimes referred to as "system date format" or "system timestamp format." But the internal description is known as "MI time" format.
Standard time format is how the MI documentation sometimes refers to this value. However, the API documentation and many MI instructions (in both C and MI languages) refer to it as MI time. There is also an occasional reference to system *DTS format.
The problem you have as an RPG IV programmer is that this format cannot be easily converted to a true RPG-style timestamp (Z data type) or date and time value.
The MI time (as we'll refer to it from here out) is currently a 49-bit value that contains the number of microseconds since three minutes past noon on August 23, 1928.
These 49 bits are stored in a 64-bit (8-byte) unsigned integer. In RPG IV, this means it is a 20U0 value.
The rightmost 15 bits are currently unused, so you have to shift the bits to the right to get an accurate numeric value. In C++, you would use two greater-than symbols (>>) to accomplish this, but in RPG IV, you have to use grunt coding techniques.
The following source code illustrates the miTimeToDTS() subprocedure. It converts the 8-byte character value containing an MI time into a true RPG IV Z data type. From that value, you can move the date into a date field and the time into a time field. Or you could always modify the code to return separate date and time variables.
As a point of completeness, you can use the QWCCVTDT API to achieve similar results. To call this API to convert an MI time value to a data structure containing the date, time, and milliseconds value, you can use the following syntax:
The prototype for this API follows:
D inFmt 10A Const
D inDate 64A Const
D outFmt 10A Const
D outDate 64A OPTIONS(*VARSIZE)
D APIerrorDS LikeDS(QUSEC) OPTIONS(*VARSIZE)
The inDate and outDate parameters are not strictly defined as 64-bytes in length; however, that size seems to work for all variations of this API.
The outDate (returned value) parameter is defined as follows:
D date 8S 0
D time 6S 0
D milliSeconds 3S 0
If you run into the need to convert from MI time to RPG IV date data types, these two routines may be useful.
H Copyright('(c) 2006 by Robert Cozzi, Jr.')
D MiTimeToDTS PR Z
D miTime 8A Const
D MI_TIME_T DS Qualified Based(ptr_Nothing)
D char 8A
D microSecs 20U 0 Overlay(char)
D miTime S 8A
D myDTS S Z
// This test code to validate that the
// MiTimeToDTS() subprocedure is working.
// Results are identified in comments.
/free
// 01/01/2000 00:00:00.000000
miTime = X'8000000000000000';
myDTS = MiTimeToDTS(miTime);
// 01/01/1970 00:00:00.000000
miTime = X'4A2FEC4C82000000';
myDTS = MiTimeToDTS(miTime);
// 07/07/2053 20:57:40.263928
miTime = X'DFFFFFFFFFFF8000';
myDTS = MiTimeToDTS(miTime);
// 08/23/1928 12:03:06.314752
miTime = X'0000000000000000';
myDTS = MiTimeToDTS(miTime);
/end-free
C eval *INLR = *ON
P MiTimeToDTS B Export
D MiTimeToDTS PI Z
D miTime 8A Const
D myTime DS LikeDS(MI_TIME_T) Inz
D int S 10U 0
D myDTS S Z Inz
D nSmallSecs S 15P 0
D baseDts S Z Inz(Z'1928-08-23-12.03.06.314752')
D MicroSecs S 20U 0
D decSecs DS Qualified INZ
D nDuration 20S 0
D nSecs 20S 6 Overlay(nDuration)
D nMicroSecs 6S 0 Overlay(nDuration:15)
/free
myTime = miTime;
// Shift the miTime right, 15 bits
microSecs = %Div(myTime.microSecs:4096);
// Map the microseconds to decimal
decSecs.nDuration = microSecs;
// Add the microSeconds to the base DTS.
myDts = baseDTS + %MSeconds(decSecs.nMicroSecs);
// Clear the microSeconds.
decSecs.nMicroSecs = 0;
// Using DS trickery, copy the "seconds"
// to a work field whose size is compatible
// with the MI duration value (15P0 max).
// nSmallSecs = decSecs.nSecs;
// Add the seconds to the dts value and we're done!
myDts = myDTS + %Seconds(%dec(decSecs.nSecs:15:0));
return myDTS;
/end-free
P MiTimeToDTS E
Bob Cozzi is a programmer/consultant, writer/author, and software developer of the RPG xTools, a popular add-on subprocedure library for RPG IV. His book The Modern RPG Language has been the most widely used RPG programming book for nearly two decades. He, along with others, speaks at and runs the highly-popular RPG World conference for RPG programmers.
More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.
TRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now! Request Now.
Forms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.
Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:
Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.
IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn:
LATEST COMMENTS
MC Press Online