It's time for a few more examples of free-format code, which help you memorize the coding rules and will speed up your transition to this new coding style.

The previous TechTip introduced the rules you need to abide by to write code in free-format and provided a simple example. This time around, I'll provide additional examples and discuss a few important things you'll need to keep in mind while coding in this new way.

Let's pick up where we stopped in the previous TechTip and look at another example of how indenting improves readability. The next code samples include instructions with code blocks inside other code blocks and also show how Factor 1, not used in the example from last time, is used in free format:

C     K_MYKEY     SETLL     MYFILE

C                 IF      %EQUAL

C     K_MYKEY     READE     MYFILE

C                 DOW       NOT %EOF(MYFILE)

C                 EXCEPT   DET_REC

C                 READ     MYFILE

C                 ENDDO

C                 ELSE

C                 EXCEPT   NoDet_REC

C                  ENDIF

Once again, this should be easy as pie in free format:

/FREE

SETLL K_MYKEY MYFILE;

IF %EQUAL;

   READE K_MYKEY MYFILE;

   DOW NOT %EOF(MYFILE);

     EXCEPT DET_REC;

     READ MYFILE;

   ENDDO;

ELSE;

   EXCEPT NoDet_REC;

ENDIF;

/END-FREE

The indentation makes the different code blocks more noticeable than ever, right?

In a fixed-format piece of code, having a sequence of nested IF statements makes it hard to understand where each of them ends:

C                 IF       P_Age >= 20 and P_Sex = 'F'

C                 EVAL     W_Code = 5

C                 ELSE

C                 IF       P_Age >= 20 and P_Sex = 'M'

C                 EVAL     W_Code = 4

C                 ELSE

C                  IF       P_Age >= 30 and P_Sex = 'F'

C                 EVAL     W_Code = 10

C                 ELSE

C                 IF       P_Age >= 30 and P_Sex = 'M'

C                 EVAL     W_Code = 9

C                 ELSE

C                 EVAL    W_Code = 20

C                 ENDIF

C                 ENDIF

C                 ENDIF

C                 ENDIF

You can replace those ELSE/IF blocks of lines by a single ELSEIF to make it more readable:

C                 IF       P_Age >= 20 and P_Sex = 'F'

C                 EVAL     W_Code = 5

C                 ELSEIF   P_Age >= 20 and P_Sex = 'M'

C                 EVAL     W_Code = 4

C                 ELSEIF   P_Age >= 30 and P_Sex = 'F'

C                 EVAL     W_Code = 10

C                ELSEIF   P_Age >= 30 and P_Sex = 'M'

C                 EVAL     W_Code = 9

C                 ELSE

C                 EVAL     W_Code = 20

C                 ENDIF

It's certainly an improvement over all those sets of ELSE followed by IF, but if there is more than one instruction after the ELSEIF, it can still get a bit confusing. That doesn't happen in free-format, assuming that the proper indentation is used:

/FREE

IF P_Age >= 20 and P_Sex = 'F';

   W_Code = 5;

ELSEIF P_Age >= 20 and P_Sex = 'M';

   W_Code = 4;

ELSEIF P_Age >= 30 and P_Sex = 'F';

   W_Code = 10;

ELSEIF P_Age >= 30 and P_Sex = 'M';

   W_Code = 9;

ELSE;

   W_Code = 20;

ENDIF;

/END-FREE

Personally, I think a SELECT block is clearer than an IF/ELSEIF block. As long as you use proper indentation, either of the two solutions works, but I still prefer this:

/FREE

SELECT;

   WHEN P_Age >= 20 and P_Sex = 'F';

     W_Code = 5;

   WHEN P_Age >= 20 and P_Sex = 'M';

     W_Code = 4;

   WHEN P_Age >= 30 and P_Sex = 'F';

     W_Code = 10;

   WHEN P_Age >= 30 and P_Sex = 'M';

     W_Code = 9;

   OTHER;

     W_Code = 20;

ENDSL;

/END-FREE

Don't worry about the missing EVAL operation codes; I'll get to that in a minute. Now, let's go back to the READE example from earlier to explain something I missed:

READE K_MYKEY MYFILE;

Notice how the READE line is written:

<Operation Code> <Factor 1> <Factor 2>

That's different from the usual format:

<Factor 1> <Operation Code> <Factor2>

This is just one of the things you need to get used to.

There are other things that might confuse you, such as the fact that EVAL and CALLP are optional, except when you need to use their extenders. You probably noticed this in the IF/ELSEIF example I just presented. The missing EVALs will seem a bit alien at first, but you'll eventually get used to it!

Not everything is "strange." Let me show you something that you'll certainly like. Here's a typical fixed-format piece of code:

C     K_MYKEY     CHAIN     MYFILE

C                 IF       %FOUND(MYFILE)

C                 EXSR     CustFound

C                 ELSE

C                 EXSR     NoCust

C                 ENDIF

Now, let's take advantage of the possibility of having longer names to make this clearer in free-format:

/FREE

CHAIN KEY MYFILE;

IF %FOUND(MYFILE);

   EXSR Customer_Found;

ELSE;

   EXSR Customer_Not_Found;

ENDIF;

/END-FREE

You have to admit that Customer_Not_Found is clearer than NoCust. This can be made even clearer with a few comments:

/FREE

CHAIN KEY MYFILE;

IF %FOUND(MYFILE);

   EXSR Customer_Found; // Retrieve customer info

ELSE;

   EXSR Customer_Not_Found; // Fill fields with N/A

ENDIF;

/END-FREE

Unlike in fixed-format, where comments need a line for themselves, in free-format you can mix code and comment in the same line, which allows for more precise and unobtrusive documentation. This is also an interesting approach to "modern" languages, where this in-line commenting is common.

Speaking of modern languages, here's something else that might be a bit confusing: you remember this line from the EVAL example, right? This code…

C                 EVAL     W_Some_Number = W_Some_Number + 1

…became this:

W_Some_Number = W_Some_Number + 1;

Well, there's another, shorter notation in free-format that RPG got from "modern" languages:

W_Some_Number += 1;

You'll find this particular form (+= 1) frequently in counter variables. This is called compound assignment, and you can use it with the following operators:

• target += expression: The expression is added to the target.
• target -= expression: The expression is subtracted from the target.
• target *= expression: The target is multiplied by the expression.
• target /= expression: The target is divided by the expression.
• target **= expression: The target is assigned the target raised to the power of the expression.

For instance, the following cuts W_Some_Number in half:

W_Some_Number /= 2

I hope that you're now convinced, ready, and willing to start converting your code to free-format. It's an easy process, but there are some pitfalls. The next TechTips will provide valuable information on how you can start converting your code and finally leave one of the biggest anachronisms of RPG behind!

Rafael Victória-Pereira has more than 20 years of IBM i experience as a programmer, analyst, and manager. Over that period, he has been an active voice in the IBM i community, encouraging and helping programmers transition to ILE and free-format RPG. Rafael has written more than 100 technical articles about topics ranging from interfaces (the topic for his first book, Flexible Input, Dazzling Output with IBM i) to modern RPG and SQL in his popular RPG Academy and SQL 101 series on mcpressonline.com and in his books Evolve Your RPG Coding and SQL for IBM i: A Database Modernization Guide. Rafael writes in an easy-to-read, practical style that is highly popular with his audience of IBM technology professionals.

Rafael is the Deputy IT Director - Infrastructures and Services at the Luis Simões Group in Portugal. His areas of expertise include programming in the IBM i native languages (RPG, CL, and DB2 SQL) and in "modern" programming languages, such as Java, C#, and Python, as well as project management and consultancy.

---

MC Press books written by Rafael Victória-Pereira available now on the MC Press Bookstore.

		Evolve Your RPG Coding: Move from OPM to ILE...and Beyond Transition to modern RPG programming with this step-by-step guide through ILE and free-format RPG, SQL, and modernization techniques. List Price $79.95 Now On Sale
		Flexible Input, Dazzling Output with IBM i Uncover easier, more flexible ways to get data into your system, plus some methods for exporting and presenting the vital business data it contains. List Price $79.95 Now On Sale
		SQL for IBM i: A Database Modernization Guide Learn how to use SQL’s capabilities to modernize and enhance your IBM i database. List Price $79.95 Now On Sale