This article expands the exploration of prototypes into the realm of subprocedures and explains how they can be used to replace subroutines.

In a previous article, I showed you how to use a prototype to replace the PLIST in your programs. In this second installment of Prototyping for Productivity, I'll show you how and why you would replace a subroutine with a subprocedure. The third and final article in the series will work with some of the keywords.

What Is a Subprocedure?

The easiest way to define a subprocedure is as a subroutine with parameters. Most languages have this concept; procedural languages such as C usually use the term procedure or function while object-oriented languages refer to methods. Generally speaking, a program invokes a function and passes it parameters, and the function optionally returns a value.

   myReturnValue = myFunction( aParm, anotherParm);

Subroutines and the EXSR Opcode

Until the advent of ILE, RPG had no equivalent to other languages' subprocedures. You could call a subroutine using the EXSR opcode, but EXSR didn't allow you to specify parameters. Part of this is due to the nature of RPG prior to ILE, where all variables are global in scope and thus available to every other line of code. To pass parameters to a subroutine, the typical RPG program has one or more global variables that the subroutine is coded to recognize. The calling part of the code initializes those variables and then calls the subroutine. The subroutine modifies another global variable to return the results. Let's take a look at a simple example. This program is the precursor to an XML formatter: it generates a tag with data. In fact, it generates two tags and then concatenates them before sending them to the user.

A h option(*srcstmt: *nodebugio)

B d ShowData        pr                  extpgm('PRO1SND')

B d   Data                       512a

C d ATag            s             10a

C d AValue          s             80a

C d ATaggedValue    s            128a

D d aBuffer         s            512a

   /free

E   aTag = 'FIELD1';

E   aValue = 'Field 1 Value';

E   exsr TagThis;

E   aBuffer = aTaggedValue;

F   aTag = 'FIELD2';

F   aValue = 'Field 2 Value';

F   exsr TagThis;

F   aBuffer = %trim(aBuffer) + aTaggedValue;

G   ShowData( aBuffer);

G   *inlr = *on;

H   begsr TagThis;

H     aTaggedValue = '<' + %trim(aTag) + '>' +

H                    %trim(aValue) +

H                    '</' + %trim(aTag) + '>';

H   endsr;

   /end-free

A: My standard H-spec. At the very least, I like to specify *SRCSTMT to make my error messages match my source line numbers. *NODEBUGIO is not needed since I don't have any files, but it doesn't hurt anything.

B: This is the prototype to call PRO1SND, a simple CL program that just sends the value in parameter Data to the user via SNDPGMMSG. An interesting point here is that a prototyped call to an external program is not an ILE construct. You can still compile this program to the default activation group. However, once you add internal prototypes, your compiles will require the DFTACTGRP(*NO) setting.

C: These are the global variables used by TagThis. This program uses variables that are pretty much exclusive to the TagThis subroutine, but this is a trivial example program. In the real world, you will find situations in which the parameters (and even the result field!) may be database or screen fields. This sort of side effect is something to be avoided at all costs, but it's almost required by the nature of pre-ILE syntax.

D: This is the working storage for this program: a buffer that will be filled with the results of the calls to the TagThis subroutine.

E: The first call to TagThis creates a tag called FIELD1 with a value of 'Field 1 Value'. The program must initialize the two parameters, invoke the subroutine, and then finally store the resulting value into the aBuffer variable.

F: The second call is almost identical, except that the value is concatenated onto the existing value (note the use of %trim).

G: This is the call to the external program PRO1SND to send the result to the user, and then the program sets on LR to get out.

H: This is the TagThis subroutine. It uses the tag value in aTag to bracket the value in aValue. It employs the standard XML tagging concept of using an opening tag and then a closing tag with the same value preceded by a slash ('/') to indicate the close.

The result is this:

<FIELD1>Field 1 Value</FIELD1><FIELD2>Field 2 Value</FIELD2>

Pretty simple. Each value is encapsulated in a tag. You can see how this could then be used to, for instance, build a list of tagged values for an XML document. This is just a tiny subset of the required work; a real XML generator is a lot larger, since it has to handle things like attributes and nested tags and escape characters.

Converting the Subroutine into a Subprocedure

So the code is not necessarily even complete. However, the point of this exercise is not to make a complete XML generator but to show how to move from a subroutine-based program design to a procedure-based architecture. Phase I of such a migration is very straightforward. I'll change the subroutine to a procedure and add all the global variables as parameters:

A h option(*srcstmt: *nodebugio) dftactgrp(*no) actgrp(*new)

B d ShowData        pr                  extpgm('PRO1SND')

B d   Data                       512a

C d TagThis         pr

C d   Tag                         10a

C d   Value                       80a

C d   TaggedValue                128a

D d ATag            s             10a

D d AValue          s             80a

D d ATaggedValue    s            128a

E d ABuffer         s            512a

   /free

F   aTag = 'FIELD1';

F   aValue = 'Field 1 Value';

F   TagThis( aTag: aValue: aTaggedValue);

F   aBuffer = aTaggedValue;

G   aTag = 'FIELD2';

G   aValue = 'Field 2 Value';

G   TagThis( aTag: aValue: aTaggedValue);

G   aBuffer = %trim(aBuffer) + aTaggedValue;

H   ShowData( aBuffer);

H   *inlr = *on;

   /end-free

I p TagThis         b

I d                 pi

I d   Tag                         10a

I d   Value                       80a

I d   TaggedValue                128a

I  /free

I   TaggedValue = '<' + %trim(Tag) + '>' +

I                 %trim(Value) +

I                 '</' + %trim(Tag) + '>';

I  /end-free

I    p                 e                 

A: I added the DFTACTGRP(*NO) and ACTGRP(*NEW) keywords to my H-spec. I could have specified these values on the compile, but I like the code to be self-documenting when possible. I'm not going to go into a discussion on activation groups; that's a big topic. *NEW is a good option for things called from a menu or from a command line.

B: Same as B on the previous listing.

C: This is the internal prototype for the TagThis subprocedure. This formally declares the parameters that will be passed.

D and E: These match up to C and D, respectively, in the previous listing.

F: This is roughly the same code as E in the previous listing, except that I used the TagThis prototype to invoke the subprocedure. Note that this is technically a CALLP instruction, but free-format RPG allows you to invoke a subprocedure with just its name; the actual CALLP opcode is optional. Setting the input variables and storing the result into the aBuffer field are very much the same as the previous listing.

G: Same as F in the previous listing, and a duplicate of the F section in this listing except using the FIELD2 values.

H: Same as G on the previous listing.

I: This is the highlight of the listing. The code that was originally in the subroutine TagThis is now is a procedure TagThis. You'll note that TagThis does not touch the global variables ATag, AValue, and AtaggedValue; instead, it works on the internal values Tag, Value, and TaggedValue, all of which are parameters to the procedure.

The fundamental difference between subprocedures and subroutines is the parameter list. In a syntactical style unique to RPG, the parameter list is defined both in section C, where it is called the prototype (hence the PR in the specification), and at the beginning of section I, where it is called the procedure interface (thus the PI designation). This two-part definition allows you to define prototypes that access external procedures and programs consistently with those for internal subprocedures. It does require what feels like double entry, but there's no way around it.

So What Have We Done?

The result of my machinations is that the code that was originally in a global subroutine is now embedded in a protoyped procedure. You may wonder what I've gotten out of this, since I've added the complexity of prototypes without actually reducing any code. I had to add the prototype and the procedure interface, and the mainline has exactly the same number of lines of code; in fact, except for the call to the subprocedure, the mainline code is exactly the same. So why bother with subprocedures at all?

Well, that's because it will allow us to take advantage of some really cool programming techniques down the line. In another article, I'll show you the simple changes to the prototype that will allow you to change the entire mainline to this:

  aBuffer = TagThis( 'FIELD1': 'Field 1 Value') +

            TagThis( 'FIELD2': 'Field 2 Value');

This is where procedures really shine: they allow you to encapsulate the details of your programming mechanics in such a way that your application programming becomes simple and easy to read. I'm looking forward to bringing that code to you later.