Take advantage of the Copy Numeric Value (CPYNV) MI instruction.

Last month, in the article "In Search of Decimal Data Errors," we saw how the List Fields (QUSLFLD) API can be used to find all numeric fields, within a user-specified file record format, that are defined as either zoned decimal or packed decimal. This month, we'll look at one approach to testing the values of each of these zoned decimal and packed decimal fields for decimal data errors.

The solution we will be using is based on the Copy Numeric Value (CPYNV) Machine Interface (MI) instruction. Similar to an RPG eval operation such as SomeNumber = AnotherNumber;, the CPYNV instruction can be used to copy a numeric value from a source variable to a target variable. CPYNV and eval share many features, such as supporting source and target variables of different data types (for instance, the source variable AnotherNumber being packed decimal while the target variable SomeNumber is zoned decimal) and detecting decimal data errors while performing the assignment. A key advantage of the CPYNV instruction, though, when compared to the RPG eval operation, is that the variable names of the source and target variables do not need to be known in advance (actually, the variable names don't even need to be known at run time, though we'll want the names so we can identify any decimal data errors by field name), and even data attributes such as type, number of digits, and scale of the source and target variables do not need to be known until run time. For a general-purpose utility designed to locate decimal data errors in any physical file defined using DDS—one of the initial requirements from last month's article—this is a rather important distinction between eval and CPYNV.

The CPYNV instruction defines four parameters. The parameters are, respectively, the address of the target variable, the attributes of the target variable (data type, total number of digits, and number of fractional digits), the address of the source variable, and the attributes of the source variable.

The attribute information parameters are defined as 7-byte input data structures with the following subfields:

• The first subfield is a 1-byte character field defining the data type. For the purposes of this article, we are only interested in two values: x'02' indicating that the associated data variable is zoned decimal and x'03' indicating that the associated data variable is packed decimal.
• The second subfield, when the previous data type is x'02' or x'03', is a 1-byte unsigned integer defining the fractional digits (number of digits to the right of the decimal point) for the associated data variable.
• The third subfield, when the previous data type is x'02' or x'03' is a 1-byte unsigned integer defining the total number of digits for the associated data variable.
• The fourth subfield is a 4-byte reserved field that must be set to x'00000000'.

The value specified for the total number of digits can, for data defined as zoned or packed decimal, be in the range of 1 to 63. The value specified for the number of fractional digits can be in the range of 0 to the total number of digits.

If you refer back to last month's article and the data mapping we performed while loading the NumFldsArray from the QUSLFLD API field information, you will find that the first subfield of the attribute information parameter maps to the variable NumFlds.Type, the second subfield maps to NumFlds.Scale, the third subfield maps to NumFlds.Digits, and the fourth subfield maps to the unnamed 4-byte integer defined within NumFlds following NumFlds.Digits. Due to this earlier mapping, and the use of NumFlds data structure overlays, the field NumFlds.SrcAttr is "conveniently" ready to be used as an attribute information parameter of the CPYNV instruction.

The Updated FNDDDE Program

With this background information on the CPYNV instruction out of the way, here is the latest version of the FNDDDE program. The changes from last month are shown in bold.

h DftActGrp(*No)                                                    

fFileX     if   f32766       disk   extfile(FileXVar) usropn      

f                                    infds(FileXDS)                

dFndDDE           pr                 extpgm('FNDDDE')              

d File_In                       10a   const                          

d Lib_In                       10a   const                          

dFndDDE           pi                                                

d File_In                      10a   const                          

d Lib_In                       10a   const                          

*********************************************************************

d CpyN           pr                 extproc('_LBCPYNV')            

d Rcv                               like(Target)            

d RcvAttr                       7a  const                    

d Src                               const like(Source)      

d SrcAttr                       7a   const                    

d CrtUsrSpc       pr                extpgm('QUSCRTUS')      

d QualName                     20a   const                    

d XtndSpcAttr                 10a   const                    

d IntSize                     10i 0 const                    

d IntValue                      1a   const                    

d PubAut                       10a   const                    

d Text                         50a   const                    

d Replace                     10a   const options(*nopass)  

d ErrCde                            likeds(QUSEC)            

d                                     options(*nopass)        

d Domain                       10a   const options(*nopass)  

d TfrSiz                       10i 0 const options(*nopass)  

d OptSpcAlgn                    1a   const options(*nopass)      

d GetFDefn       pr                                              

d LogNbrError     pr                                              

d LstFld         pr                 extpgm('QUSLFLD')          

d QualUsrSpc                   20a   const                        

d Format                       8a   const                      

d QualFileName                 20a   const                      

d RcdFmt                       10a   const                      

d OvrPrc                       1a  const                      

d ErrCde                             likeds(QUSEC)              

d                                     options(*nopass)            

d RtvFD           pr                 extpgm('QDBRTVFD')          

d RcvVar                       1a   options(*varsize)          

d LenRcvVar                   10i 0 const                

d QualNameRtn                 20a                        

d Format                        8a   const                

d QualFileName                 20a   const                

d RcdFmt                       10a   const                

d OvrPrc                       1a   const                

d System                      10a   const                

d FmtType                     10a   const                

d ErrCde                             likeds(QUSEC)        

d RtvUsrSpcPtr   pr                 extpgm('QUSPTRUS')  

d QualUsrSpc                   20a   const                

d UsrSpcPtr                     *                        

d ErrCde                             likeds(QUSEC)        

d SndEscMsg       pr                                      

d MsgID_In                     7a   const                

d MsgDta_In                   256a   const                    

d SndPgmMsg       pr                 extpgm('QMHSNDPM')        

d MsgID                         7a   const                    

d MsgFile                     20a   const                    

d MsgDta                     256a   const options(*varsize)  

d LenMsgDta                   10i 0 const                    

d MsgType                     10a   const                    

d CSE                         10a   const options(*varsize )  

d CSECtr                       10i 0 const                    

d MsgKey                       4a                            

d ErrCde                             likeds(QUSEC)            

d                                     options(*varsize)        

d LenCSE                     10i 0 const options(*nopass)    

d QualCSE                     20a   const options(*nopass)    

d WaitTime                     10i 0 const options(*nopass)    

d CSEDtaType                   10a   const options(*nopass)    

d CCSID                        10i 0 const options(*nopass)        

d SndSysMsg       pr                                                

*********************************************************************

d CpyNFailure     c                   const(00202)                  

d MaxNbrNumFlds   c                   const(1000)                    

d Packed         c                   const(x'03')                  

d SpcSize         c                   const(1048576)                

d Zoned           c                   const(x'02')                  

*********************************************************************

* Structures related to API QDBRTVFD                                

d myQDBQ25_Ptr   s               *                                  

d myQDBQ25       ds                 likeds(QDBQ25)        

d                                    based(myQDBQ25_Ptr)  

d myQDBQ36_Ptr   s               *                        

d myQDBQ36       ds                 likeds(QDBQ36)        

d                                     based(myQDBQ36_Ptr)  

* Structures related to API QUSLFLD                        

d LstFldHdr_Ptr   s               *                          

d LstFldHdr       ds                 likeds(QUSH0100)      

d                                     based(LstFldHdr_Ptr)  

d LstFld100_Ptr   s               *                          

d LstFld100       ds                 likeds(QUSL0100)      

d                                     based(LstFld100_Ptr)  

d CurNbrNumFlds   s             5u 0                            

d NumFlds         ds                 qualified                  

d NumFldsArray                 21a   dim(MaxNbrNumFlds)        

d   FldName                     10a   overlay(NumFldsArray :1)  

d   Bytes                       5u 0 overlay(NumFldsArray :11)  

d   SrcAttr                     7a   overlay(NumFldsArray :13)  

d   Type                       1a   overlay(SrcAttr :1)        

d   Scale                       3u 0 overlay(SrcAttr :2)        

d   Digits                     3u 0 overlay(SrcAttr :3)        

d                               10i 0 overlay(SrcAttr :4)        

d                                     inz(0)                    

d   BfrStrPos                   5u 0 overlay(NumFldsArray :20)  

d FileXDS         ds                                            

d RelNo               397   400i 0                            

d PSDS           sds                                

d ExcpID               40     46a                

d ErrCde         ds                 qualified                  

d Hdr                               likeds(QUSEC)                  

d MsgDta                     256a                                  

*********************************************************************

d BlnkNbr         s             20i 0                                

d FileXVar       s             21a                                  

d GoodNbr         s             20i 0                                

d MsgDta         s           256a                                  

d MsgKey         s             4a                                  

d NonBlnkNbr     s             20i 0                                

d NotMCH1202     s              n                                  

d QualNameRtn     s             20a                                  

d RcdFmt         s             10a                                  

d Source         s           100a   based(Source_Ptr)              

d Source_Ptr     s               *                                  

d Target         s           100a                                  

d X               s             10i 0                                

*********************************************************************

/copy qsysinc/qrpglesrc,qdbrtvfd                                    

/copy qsysinc/qrpglesrc,qusec                                      

/copy qsysinc/qrpglesrc,qusgen                                      

/copy qsysinc/qrpglesrc,quslfld                                    

*********************************************************************

iFileX     ns                                                        

i                                 132766 InpBfr                    

*********************************************************************

/free                                                      

dsply ('List of ' +                                      

       %trimr(File_In) +                                  

         ' fields with problems:');                        

read FileX;                                                    

dow (not %eof(FileX));                                          

     for X = 1 to CurNbrNumFlds;                      

         Source_Ptr = %addr(InpBfr) + NumFlds.BfrStrPos(X) - 1;  

         monitor;                                                

             CpyN(Target :NumFlds.SrcAttr(X)                      

                 :Source :NumFlds.SrcAttr(X));                    

             GoodNbr += 1;                                        

         on-error CpyNFailure;                                  

             if ExcpID = 'MCH1202';    

               LogNbrError();        

             else;                    

               NotMCH1202 = *on;      

             endif;                    

         on-error *all;                                          

             NotMCH1202 = *on;                                    

         endmon;          

     endfor;              

     read FileX;          

enddo;

close FileX;

dsply (%char(GoodNbr) + ' good values found');        

dsply (%char(BlnkNbr) + ' blank values found');        

dsply (%char(NonBlnkNbr) + ' non-blank values found');

if NotMCH1202;                                        

     dsply 'Other numeric errors also found';            

endif;                                                

dsply ' Press Enter to continue' ' ' MsgKey;          

*inlr = *on;                                          

return;                                                

// *****************************************************************

begsr *inzsr;                                                      

   // Set API QUSEC parameter to send exceptions                    

   QUSBPrv = 0;                                                    

   // Set API ErrCde parameter to not send exceptions              

   ErrCde.Hdr.QUSBPrv = %size(ErrCde);                              

   GetFDefn();                                                      

   // Get list of File_In fields and field attributes              

   RtvUsrSpcPtr('QUSLFLD   QTEMP' :LstFldHdr_Ptr :ErrCde);      

   if ErrCde.Hdr.QUSBAvl > 0;                                  

       if ErrCde.Hdr.QUSEI = 'CPF9801';                          

         // Create user space if not found                      

         CrtUsrSpc('QUSLFLD   QTEMP' :' ' :SpcSize :x'00'      

                   :'*ALL' :'UsrSpc for QUSLFLD output'        

                   :'*YES' :QUSEC :'*USER' :0 :'1');            

         RtvUsrSpcPtr('QUSLFLD   QTEMP' :LstFldHdr_Ptr :QUSEC);

       else;                                                    

         // Any other error is a hard failure                  

         SndSysMsg();                                          

       endif;                                                    

   endif;                                                      

   LstFld('QUSLFLD   QTEMP' :'FLDL0100'                            

         :(File_In + Lib_In) :RcdFmt :'0' :QUSEC);                

   for X = 1 to LstFldHdr.QUSNbrLE;                                

       if X = 1;                                                  

           LstFld100_Ptr = LstFldHdr_Ptr + LstFldHdr.QUSOLD;        

       else;                                                      

           LstFld100_Ptr += LstFldHdr.QUSSEE;                      

       endif;                                                      

       // Load up numeric fields into NumFldsArray                

       select;                                                    

           when LstFld100.QUSDT = 'S';                              

               CurNbrNumFlds += 1;                                

               NumFlds.FldName(CurNbrNumFlds) = LstFld100.QUSFN02;

               NumFlds.Bytes(CurNbrNumFlds) = LstFld100.QUSFLB;    

               NumFlds.Type(CurNbrNumFlds) = Zoned;                

               NumFlds.Scale(CurNbrNumFlds) = LstFld100.QUSDP;    

               NumFlds.Digits(CurNbrNumFlds) = LstFld100.QUSigits;

                NumFlds.BfrStrPos(CurNbrNumFlds) = LstFld100.QUSIBP;

           when LstFld100.QUSDT = 'P';                              

               CurNbrNumFlds += 1;                                

               NumFlds.FldName(CurNbrNumFlds) = LstFld100.QUSFN02;

               NumFlds.Bytes(CurNbrNumFlds) = LstFld100.QUSFLB;    

               NumFlds.Type(CurNbrNumFlds) = Packed;              

               NumFlds.Scale(CurNbrNumFlds) = LstFld100.QUSDP;    

               NumFlds.Digits(CurNbrNumFlds) = LstFld100.QUSigits;

               NumFlds.BfrStrPos(CurNbrNumFlds) = LstFld100.QUSIBP;

          other;                                                  

               // Don't care about other types                      

       endsl;                                                      

   endfor;                                                          

   FileXVar = %trimr(Lib_In) + '/' + %trimr(File_In);              

   open FileX;                                                      

endsr;                                                            

/end-free                                                          

*********************************************************************

p LogNbrError     b                                                  

d LogNbrError     pi                                                

/free                                                              

dsply (%trimr(NumFlds.FldName(X)) +                                

         ' of relative record ' +                                    

         %char(RelNo));                                              

if %subst(Source :1 :NumFlds.Bytes(X)) = *blanks;                  

     BlnkNbr += 1;                                                    

else;                                                              

     NonBlnkNbr += 1;                                                

endif;                                                              

/end-free                                                            

p LogNbrError     e                                                  

**********************************************************************

p SndSysMsg       b                                                  

d SndSysMsg       pi                                                  

/free                                                              

if ErrCde.Hdr.QUSBAvl <= 16;                                      

     SndEscMsg(ErrCde.Hdr.QUSEI :' ');                              

else;                                                              

     SndEscMsg(ErrCde.Hdr.QUSEI                                      

               :%subst(ErrCde.MsgDta :1                              

                :(ErrCde.Hdr.QUSBAvl - 16)));                      

endif;                                                            

/end-free                                                            

p SndSysMsg       e                                                  

*********************************************************************

p SndEscMsg       b                                                  

d SndEscMsg       pi                                                

d MsgID_In                     7a   const                          

d MsgDta_In                   256a   const                          

/free                                                              

SndPgmMsg(MsgID_In :'QCPFMSG   *LIBL'                              

           :MsgDta_In :%len(%trimr(MsgDta_In))                      

           :'*ESCAPE' :'*PGMBDY' :1                                

         :MsgKey :QUSEC);                                        

/end-free                                                          

p SndEscMsg       e                                                  

*********************************************************************

p GetFDefn       b                                                  

d GetFDefn       pi                                                

/free                                                          

   // Get File_In definition and record format name            

   RtvUsrSpcPtr('QDBRTVFD QTEMP' :myQDBQ25_Ptr :ErrCde);      

   if ErrCde.Hdr.QUSBAvl > 0;                                  

       if ErrCde.Hdr.QUSEI = 'CPF9801';                          

         // Create user space if not found                      

         CrtUsrSpc('QDBRTVFD QTEMP' :' ' :SpcSize :x'00'      

                   :'*ALL' :'UsrSpc for QDBRTVFD output'        

                  :'*YES' :QUSEC :'*USER' :0 :'1');            

         RtvUsrSpcPtr('QDBRTVFD QTEMP' :myQDBQ25_Ptr :QUSEC);  

       else;                                                      

         // Any other error is a hard failure                    

         SndSysMsg();                                            

       endif;                                                      

   endif;                                                        

   RtvFD(myQDBQ25 :SpcSize :QualNameRtn :'FILD0100'              

         :(File_In + Lib_In) :'*FIRST' :'0' :'*LCL'              

         :'*EXT' :ErrCde);                                        

   if ErrCde.Hdr.QUSBAvl > 0;                                    

       SndSysMsg();                                                

   endif;                                                        

   if %bitand(%subst(myQDBQ25.QDBBits27 :1 :1) :x'20') = x'20';  

       MsgDta = %trimr(Lib_In) + '/' + %trimr(File_In) +          

               ' is not a table/physical file. Command ended';    

       SndEscMsg('CPF9898' :MsgDta);                        

   endif;                                                  

   // Get record format name                              

   myQDBQ36_Ptr = myQDBQ25_Ptr + myQDBQ25.QDBFOS;          

   RcdFmt = myQDBQ36.QDBFT01;                              

/end-free                                                  

p GetFDefn       e                                        

The first changes in FNDDDE from last month are related to accessing the file identified by the File_In and Lib_In parameters passed to the program. Previously FNDDDE, in the initialization subroutine *INZSR, verified that the physical file existed and then consolidated information related to all zoned decimal and packed decimal fields into the array NumFlds.NumFldsArray. The change in the initialization subroutine is that FNDDDE now also opens the file identified by File_In and Lib_In as FileX using the variable FileXVar.

FileX is defined as an input-only, program-described file with a maximum record length of 32766 bytes. The input specifications associated with FileX define one input field, InpBfr (Input Buffer), as a character variable with a length of 32766 bytes. The file is explicitly opened by the program (file-description keyword usropn) with the file name to be used at open time identified by the variable FileXVar (file-description keyword extfile). Associated with FileX is the feedback information data structure FileXDS (file-description keyword infds). The FileXDS data structure defines one subfield, RelNo, which will be updated with the relative record number of each record read from FileX. This relative record number field is used by FNDDDE as one way to identify any record found to contain decimal data errors. In a future article, we'll also identify any record found to contain decimal data errors by key in addition to by relative record number.

The updated FNDDDE program also includes the following minor changes:

• Prototyping the CPYNV MI instruction (using the name CpyN)
• Prototyping a new function LogNbrError that is used to log decimal data errors
• Defining a named constant, CpyNFailure, with a value of 00202. This value represents the RPG %status value of a called procedure failing. In the case of FNDDDE, the failing procedure would be the CPYNV MI instruction.
• Defining a program status data structure (PSDS). This is done to provide access to the error message ID, causing the RPG %status value to be set to a procedure failure.
• Defining several additional work fields associated with keeping track of the decimal data processed by the program. As an example, the variable BlnkNbr is used to maintain a running count of the instances where a FileX field was found to have a decimal data error due to the field being set to all blanks.
• A wording change to the dsply operation found at the start of FNDDDE's mainline: changing the text 'fields to be tested:' to 'fields with problems:'

Moving on to actually finding the problem fields, the changes in the mainline of FNDDDE are these:

1. read the first record of FileX

2. Enter a dow group conditioned by a record being successfully read from FileX

3. For every record read, enter a for group conditioned by the number of zoned decimal and packed decimal fields that are defined within the record format of FileX. Within the for group, for each zoned and packed decimal field defined…

• Set the pointer variable Source_Ptr to the address of each zoned decimal or packed decimal field within the record format. The based variable Source then refers to the start of the decimal field within the input buffer InpBfr
• Start a monitor group
• Copy the zoned or packed decimal field addressed by Source to the variable Target. The copy is done using the CPYNV MI instruction, which validates the encoding of the source decimal field as part of the copy operation. During the copy operation, we use NumFlds.SrcAttr to define the attributes of the numeric data being copied and simply copy the data to a new location without changing the data type
• When no error is encountered by the CPYNV instruction, FNDDDE then adds 1 to the working variable GoodNbr. This variable is used to count the instances of "good" data being found in a zoned or packed decimal field. The for group then proceeds to the next decimal field defined within the record being processed.
• When an error is encountered, one of two on-error blocks will be run. If the failure occurred with the CPYNV instruction (the on-error status is equal to CpyNFailure), FNDDDE first verifies that the failure was indeed due to a MCH1202 (Decimal data error) and, if so, runs function LogNbrError(). In any other situation (that is, the error was not a MCH1202 or the on-error status was not equal to CpyNFailure), FNDDDE simply sets the indicator variable NotMCH1202 to *on to indicate a non-MCH1202 error situation was encountered. The for group then proceeds to the next decimal field defined with the record being processed

4. When the for group is exited, having checked all defined decimal fields, read the next record of FileX and resume at step 2 above.

5. When the dow group is exited, having processed all records within FileX, close FileX, dsply summary information concerning the data found within FileX, and exit the program. The summary information is the number of valid decimal values found, the number of decimal data errors found due to the data being set to all blanks, and the number of decimal data errors found due to non-blank data.

This month, the processing within the LogNbrError() function is pretty minimal. The function is run out of one of the on-error blocks when a decimal data error is found and uses the dsply operation to display the name of the field that encountered the error, as well as the relative record number of the record containing the field, and then increments one of two variables. If the field having a decimal data error is all blanks, then variable BlnkNbr is incremented by one; otherwise, variable NonBlnkNbr is incremented. These variables are used for summary information when the FNDDDE program has completed processing of FileX. In future articles, we'll see this function providing quite a bit more information related to the decimal data error.

Assuming that you store the preceding source in member FNDDDE of QRPGLESRC, then you can create the utility program using this command:

CRTBNDRPG PGM(FNDDDE)

Testing the FNDDDE Program

Last month, we created the test file DDEDATA in order to test the listing of all zoned decimal and packed decimal field names defined within a file. Today, we'll write a program that will load some "good" numeric values into DDEDATA, along with some rather "questionable" data. We'll use this data to then test our FNDDDE changes.

The program to load data into DDEDATA uses two file description specifications—DDEDATA and DDEDATAP—with both being directed to the physical file DDEDATA. The DDEDATA file description uses the external definition of the DDEDATA file and is used when writing good numeric values. The DDEDATAP file description uses a program-described definition of the DDEDATA file and is used when writing questionable numeric values. Both file descriptions are defined as block(*no) so that the records being written to the physical file DDEDATA are interspersed with data from both file descriptions. Basically, records with relative record numbers of 1, 3, and 5 represent good data, while the records found with relative record numbers 2, 4, and 6 contain questionable data.

Special notes related to the following program:

1. The data associated with the sixth record being written (the character string '()E5q?xyz1-/"s0AT0J0D') may appear to you as being random gibberish. From a natural language point of view, it is indeed gibberish, but it is definitely not random and was selected with some care, so recreate the string in your source code as it is provided below.

2. If you typically work in the Japanese language environment using CCSID 5026, make sure when entering and compiling the following source code that you are working in a CCSID such as 5035 and code page 1027. This note applies to the data used for both records 4 and 6.

3. If you typically work in a Turkish language environment using either CCSID 905 or 1026, replace the quotation mark/double apostrophe (") with the Latin capital letter U with diaeresis (Ü). This note applies to the data used for record 6.

4. Other national language environments should have no special considerations (which is part of my previously mentioned "selecting with some care" the characters being used).

The following program can be used to load DDEDATA with six records.

fDDEData   o a e             disk   block(*no)            

fDDEDataP o a f   33       disk   extfile('DDEDATA')    

f                                     block(*no)            

d PgmDta         s             33a                        

/free                                                      

SomeKey = 'Good_Data_1';                                  

ChrFld1 = 'A';                                            

ZndFld1 = 1;                                              

PkdFld1 = 1;                                              

ChrFld2 = 'B';                                            

ZndFld2 = 2.1;                                            

PkdFld2 = 2.1;                                            

ZndFld3 = 20130101;                                      

write Record;                              

PgmDta =                                    

   'Bad_Data?_1 B     B001001       ';      

except WrtPgmDta;                          

SomeKey = 'Good_Data_2';                    

ChrFld1 = 'C';                              

ZndFld1 = 3;                                

PkdFld1 = 3;                                

ChrFld2 = 'D';                              

ZndFld2 = 4.1;                              

PkdFld2 = 5.1;                              

ZndFld3 = 20130102;                        

write Record;                              

PgmDta =                                    

   'Bad_Data?_2 BadDataIsPossibleHere';    

except WrtPgmDta;                        

SomeKey = 'Good_Data_3';                  

ChrFld1 = 'E';                            

ZndFld1 = 5;                              

PkdFld1 = 5;                              

ChrFld2 = 'F';                            

ZndFld2 = 14.1;                          

PkdFld2 = 15.1;                          

ZndFld3 = 20130103;                      

write Record;                            

PgmDta =                                  

   'Bad_Data?_3 ()E5q?xyz1-/"s0AT0J0D';    

except WrtPgmDta;                        

*inlr = *on;                                    

return;                                          

/end-free                                        

oDDEDataP eAdd         WrtPgmDta                  

o                       PgmDta             33    

Assuming that you store the preceding source in member LOADDDE of QRPGLESRC and have previously created the physical file DDEDATA defined in the earlier article, you can create and run the program using these commands:

CRTBNDRPG PGM(LOADDDE)

CALL PGM(LOADDDE)

Having loaded the sample records into DDEDATA with LOADDDE, using the command CALL PGM(FNDDDE) PARM(DDEDATA *LIBL) should result in a display similar to what's shown below.

DSPLY List of DDEDATA fields with problems:  

DSPLY ZNDFLD1 of relative record 2            

DSPLY PKDFLD1 of relative record 2            

DSPLY PKDFLD2 of relative record 2            

DSPLY ZNDFLD3 of relative record 2            

DSPLY PKDFLD1 of relative record 4            

DSPLY PKDFLD2 of relative record 4            

DSPLY ZNDFLD3 of relative record 4            

DSPLY 23 good values found                    

DSPLY 3 blank values found                    

DSPLY 4 non-blank values found                

DSPLY   Press Enter to continue              

From the above, you can see the FNDDDE program found four decimal data problems related to the second record in DDEDATA—specifically, the fields ZndFld1, PkdFld1, PkdFld2, and ZndFld3; three decimal data problems related to the fourth record in DDEDATA—specifically, the fields PkdFld1, PkdFld2, and ZndFld3; and, perhaps as a surprise to you, no decimal data problems with the sixth record (along with no problems being found in records 1, 3, or 5). In total, FNDDDE encountered 23 good numeric values, three numeric values with decimal data problems due to blanks being found, and four numeric values with decimal data problems due to non-blank values being found.

To conduct additional testing of FndDDE, you can also, for any externally described physical file X in library Y, see what records and fields of X contain decimal data errors by running this command:

CALL PGM(FNDDDE) PARM(X Y)

In next month's column, we'll make further enhancements to the FNDDDE utility. These enhancements will include identification of those decimal data errors due to blanks being found, identification of those decimal data errors due to non-blank values being found (along with the use of an API to easily see the non-blank value that was encountered), and changing from the use of the dsply operation to the use of a printer file thereby enabling FNDDDE to be run in batch.

In addition, we'll look at why the system is quite satisfied with the data associated with the sixth record in DDEDATA (along with fields such as ZndFld1 of the fourth record). If you're content to the point that if you were to use a quick DFU or SQL 'Select *' to look at the DDEDATA record with SomeKey = 'Bad_Data?_3', you would find that ZndFld1 has a value of 55, PkdFld1 a value of 986, ZndFld2 a value of 89.1, PkdFld2 a value of 606.17, and ZndFld3 a value of 20130104.

As usual, if you have any API questions, send them to me at This email address is being protected from spambots. You need JavaScript enabled to view it.. I'll see what I can do about answering your burning questions in future columns.