It's easy with the User Application Information APIs!
I received the following from reader Kiernan M.:
"Your articles are giving me all kinds of ideas for improving our system.... Is there an API that lets me recall previous usage information like how SEU does with *PRV?"
As this would be an extremely short article if this capability was unavailable, it's safe to assume that there are indeed APIs to assist you in retaining previous usage information. Starting with V5R3, IBM provides three APIs that can be used to store and retrieve application-related data on a per-user profile basis:
- •QsyUpdateUserApplicationInfo
- •QsyRetrieveUserApplication Info
- •QsyRemoveUserApplicationInfo
While SEU does not use these particular APIs (SEU's *PRV support significantly predates V5R3), these APIs provide you with the ability to associate user application information to a *USRPRF. This information can be essentially anything you want to retain across instances of application usage and is automatically saved and restored with the *USRPRF. This last point is significant as you do not need to manage the application-related information as a separate entity, which you would need to do if storing this information in a database file, user index, etc.
To get started, we will create the command Start My Application (STRMYAPP). The command will take two parameters: a qualified file name and a member name. Here's the command source:
Cmd Prompt(SMA1001)
Parm Kwd(File) Type(QualName) Prompt(SMA1002)
Parm Kwd(Mbr) Type(*Name) Len(10) Dft(*Prv) +
SpcVal((*Prv)) Prompt(SMA1004)
QualName: Qual Type(*Name) Len(10) Dft(*Prv) SpcVal((*Prv))
Qual Type(*Name) Len(10) SpcVal((*Libl) +
(*CurLib *CurLib)) Prompt(SMA1003)
The STRMYAPP command uses prompting text stored in the message file (*MSGF) USERMSGF. The following steps will create the USERMSGF *MSGF in library VINING (you might want to use a name other than VINING), add four message descriptions (*MSGD) to USERMSGF, and then create the STRMYAPP command.
CRTMSGF MSGF(VINING/USERMSGF)
ADDMSGD MSGID(SMA1001) MSGF(VINING/USERMSGF) MSG('Start My Application')
ADDMSGD MSGID(SMA1002) MSGF(VINING/USERMSGF) MSG('File')
ADDMSGD MSGID(SMA1003) MSGF(VINING/USERMSGF) MSG('Library')
ADDMSGD MSGID(SMA1004) MSGF(VINING/USERMSGF) MSG('Member')
CRTCMD CMD(VINING/STRMYAPP) PGM(VINING/SMACPP) PMTFILE(VINING/USERMSGF)
The command processing program (CPP), SMACPP, for our STRMYAPP command doesn't exist yet, but the command will create successfully all the same. In preparation for writing the SMACPP program, let's look at the Update User Application Information API, which is documented here.
This API defines seven parameters.
The first parameter, User_profile, is the name of the user profile for which application information will be updated. One special value is supported : *CURRENT. Note that this special value indicates that the current user profile, not the user profile that started the job, should be used. If you have applications that swap to a shared profile for authority purposes while running, you will most likely want to use the user profile found in the job name, not the current (shared) user profile.
The second parameter, Application_information_ID, identifies what application information is to be updated. You can have multiple applications (Order Entry, Inventory Control, Shipping, etc.) storing information with each *USRPRF. Each of these applications would have its own application ID so that information stored for one application would not conflict with information stored for another application. For STRMYAPP, the application ID will be RPG_DEVELOPER_MY_APPLICATION. The maximum length of the application ID is 200 bytes, and IBM suggests in the API documentation that certain naming conventions be followed in order to avoid application ID conflicts when running software from multiple sources. In the current case, I'm using RPG_DEVELOPER as my company name.
The third parameter, Length_of_application_information_ID, is simply the length of the second parameter. This value can be from 1 to 200. For RPG_DEVELOPER_MY_APPLICATION, this parameter will be set to 28 and calculated using RPGs %len and %trimr built-ins.
The fourth parameter, Application_information, represents the information that you want to store for the identified application. As STRMYCMD supports *PRV for the qualified file name and the member name, you will certainly want to store this information. In addition, you may also want to store user preference information, such as Full screen mode (as an example and following the SEU scenario).
The fifth parameter, Length_of_application_information, is simply the length of the fourth parameter. This value can be from 1 to 1700.
The sixth parameter, First_valid_release, identifies the first supported i5/OS release in which the application (RPG_DEVELOPER_MY_APPLICATION in this example) is valid. The system uses this when saving a *USRPRF to a previous release in order to avoid restoring application-related information to a system where the application cannot run. The format of the parameter is VxRxMx as in V5R4M0.
The seventh parameter, Error_code, is the standard API error code structure.
With that introduction, the following program demonstrates how to set default values for a new user of RPG_DEVELOPER_MY_APPLICATION.
h dftactgrp(*no)
dUpdUsrInf pr extproc(
d 'QsyUpdateUserApplicationInfo')
d UsrPrf 10 const
d ApplID 200 const options(*varsize)
d LenApplID 10i 0 const
d ApplInfo 1700 const options(*varsize)
d LenApplInfo 10i 0 const
d MinVRM 6 const
d QUSEC likeds(QUSEC)
d/copy qsysinc/qrpglesrc,qusec
dApplInfo ds 100 qualified
d File 10
d Library 10
d Member 10
d FullScreen 1
dApplID s 200 inz(
d 'RPG_DEVELOPER_MY_APPLICATION')
dMinVRM s 6 inz('V5R3M0')
/free
QUSBPRV = 0;
ApplInfo.File = 'QRPGLESRC';
ApplInfo.Library = '*LIBL';
ApplInfo.Member = '*FIRST';
ApplInfo.FullScreen = 'N';
UpdUsrInf('*CURRENT' :ApplID :%len(%trimr(ApplID))
:ApplInfo :%size(ApplInfo) :MinVRM :QUSEC);
*inlr = *on;
return;
/end-free
The program is very straightforward. It sets the Bytes provided of the error code structure to 0, which indicates that any errors found by the QsyUpdateUserApplicationInfo API should be returned as *ESCAPE messages, initializes default values for the subfields of the ApplInfo data structure, updates the application-related information for the *CURRENT user of the RPG_DEVELOPER_MY_APPLICATION application based on the ApplInfo data structure, and ends.
Note that this sample program is not the CPP for STRMYAPP. This is simply an example of using the QsyUpdateUserApplicationInfo API to set default values for a *USRPRF. In the next article, we will review the CPP SMACPP, which will have the above code imbedded in it.
Meanwhile, if you have other API questions, send them to me at
Bruce Vining is president and co-founder of Bruce Vining Services, LLC, a firm providing contract programming and consulting services to the System i community. He began his career in 1979 as an IBM Systems Engineer in St. Louis, Missouri, and then transferred to Rochester, Minnesota, in 1985, where he continues to reside. From 1992 until leaving IBM in 2007, Bruce was a member of the System Design Control Group responsible for OS/400 and i5/OS areas such as System APIs, Globalization, and Software Serviceability. He is also the designer of Control Language for Files (CLF).A frequent speaker and writer, Bruce can be reached at
MC Press books written by Bruce Vining available now on the MC Press Bookstore.
 |
||
 |
|
IBM System i APIs at Work Leverage the power of APIs with this definitive resource. List Price $89.95 Now On Sale
|
More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.
TRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now! Request Now.
Forms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.
Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:
Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.
IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn:
LATEST COMMENTS
MC Press Online