Much has been written about the library list; it's a topic that confuses enough people to deserve repeated treatment and explanations. For instance, one of the questions in everyone's mind is "How can I make sure the library list returns to its original setup after I've changed it?"

The ideal solution is to store the library list in some kind of object so that it can be retrieved later from the same object. Data areas come to mind as the repositories for library lists, except that you have to give them names, even if placed in QTEMP. So far, the best solution I've found is to use not data areas, but data queues. This approach made me write two utility commands: Save Library List (SAVLIBL) and Restore Library List (RSTLIBL).

SAVLIBL (Figure 6) uses a LIFO data queue named LIBLSTACK in QTEMP, which is created if nonexistent. Its processing program, LIBL007CL (Figure 7) takes care of everything. It retrieves the user portion of the library list, as well as the current library name, and calls QSNDDTAQ to write that information into the data queue. The first 10 characters of the entry contain the current library name, and the next 275 characters contain the user portion of the library list, in 25 eleven-byte buckets.

RSTLIBL (Figure 8) performs the opposite function: It retrieves the last entry in the data queue and changes the library list accordingly. For that, its processing program (LIBL008CL, in Figure
9) calls QRCVDTAQ, runs the Change Current Library (CHGCURLIB) command, and builds a Change Library List (CHGLIBL) command in a CL variable, which is then executed via a call to QCMDEXC.

Figure 10 shows how you can use these two commands. If you're going to run a program that needs to change the library list, code a SAVLIBL before any changes. Then, do whatever you need to do and code a RSTLIBL at the end. Because SAVLIBL and RSTLIBL use a LIFO data queue, your program may call another program, which, in turn, uses SAVLIBL and RSTLIBL. This means that SAVLIBL and RSTLIBL provide you with an unlimited number of "versions" of the library list-and you don't need to bother naming them!

SAVLIBL is smart enough to create the necessary data queue if it doesn't find it (as would be the case the first time SAVLIBL runs in a job). RSTLIBL ends with an escape message (CPF9898) if the data queue does not exist (i.e., if SAVLIBL has never run in the current job) or is empty
(i.e., if there is no corresponding SAVLIBL to the RSTLIBL you're running now). SAVLIBL and RSTLIBL must always go in pairs.

- Ernie Malaga

Figure 6: The SAVLIBL command

/*===================================================================*/

/* To compile: */
/* */
/* CRTCMD CMD(XXX/SAVLIBL) PGM(XXX/LIBL007CL) + */
/* SRCFILE(XXX/SOURCE) TEXT('Save Library List*/
/* */
/*===================================================================*/

CMD PROMPT('Save Library List') /*===================================================================*/

/* To compile: */
/* */
/* CRTCLPGM PGM(XXX/LIBL007CL) SRCFILE(XXX/SOURCE) + */
/* TEXT('CPP for SAVLIBL command') */
/* */
/*===================================================================*/

PGM

DCL VAR(&CURLIB) TYPE(*CHAR) LEN(10)
DCL VAR(&DTAQE) TYPE(*CHAR) LEN(300)
DCL VAR(&DTAQELEN) TYPE(*DEC) LEN(5) VALUE(300)
DCL VAR(&USRLIBL) TYPE(*CHAR) LEN(275)

MONMSG MSGID(CPF0000 MCH0000) EXEC(GOTO CMDLBL(ERROR))

/* Create library list stack if necessary */
CHKOBJ OBJ(QTEMP/LIBLSTACK) OBJTYPE(*DTAQ)
MONMSG MSGID(CPF9801) EXEC(DO)

RCVMSG MSGTYPE(*LAST) RMV(*YES)
CRTDTAQ DTAQ(QTEMP/LIBLSTACK) TYPE(*STD) MAXLEN(300) +

SEQ(*LIFO) TEXT('Library list stack')
ENDDO

/* Save library list into stack */
RTVJOBA USRLIBL(&USRLIBL) CURLIB(&CURLIB)
IF COND(&CURLIB *EQ '*NONE') THEN(DO)
CHGVAR VAR(&CURLIB) VALUE('*CRTDFT')
ENDDO

CHGVAR VAR(&DTAQE) VALUE(&CURLIB *CAT &USRLIBL)

CALL PGM(QSNDDTAQ) PARM('LIBLSTACK' 'QTEMP' +

&DTAQELEN &DTAQE)

RETURN

ERROR:

FWDPGMMSG
MONMSG MSGID(CPF0000)

ENDPGM /*===================================================================*/

Figure 7: CL program LIBL007CL

 /*===================================================================*/ /* To compile: */ /* */ /* CRTCLPGM PGM(XXX/LIBL007CL) SRCFILE(XXX/SOURCE) + */ /* TEXT('CPP for SAVLIBL command') */ /* */ /*===================================================================*/ PGM 
 DCL VAR(&CURLIB) TYPE(*CHAR) LEN(10)   DCL VAR(&DTAQE) TYPE(*CHAR) LEN(300)   DCL VAR(&DTAQELEN) TYPE(*DEC) LEN(5) VALUE(300)   DCL VAR(&USRLIBL) TYPE(*CHAR) LEN(275) 
 MONMSG MSGID(CPF0000 MCH0000) EXEC(GOTO CMDLBL(ERROR)) 
 /* Create library list stack if necessary */   CHKOBJ OBJ(QTEMP/LIBLSTACK) OBJTYPE(*DTAQ)   MONMSG MSGID(CPF9801) EXEC(DO)     RCVMSG MSGTYPE(*LAST) RMV(*YES)     CRTDTAQ DTAQ(QTEMP/LIBLSTACK) TYPE(*STD) MAXLEN(300) +                  SEQ(*LIFO) TEXT('Library list stack')   ENDDO 
 /* Save library list into stack */   RTVJOBA USRLIBL(&USRLIBL) CURLIB(&CURLIB)   IF COND(&CURLIB *EQ '*NONE') THEN(DO)     CHGVAR VAR(&CURLIB) VALUE('*CRTDFT')   ENDDO 
 CHGVAR VAR(&DTAQE) VALUE(&CURLIB *CAT &USRLIBL) 
 CALL PGM(QSNDDTAQ) PARM('LIBLSTACK' 'QTEMP' +                &DTAQELEN &DTAQE) 
 RETURN 
ERROR:   FWDPGMMSG   MONMSG MSGID(CPF0000) 
ENDPGM 

Figure 8: Command RSTLIBL

/* */
/* CRTCMD CMD(XXX/RSTLIBL) PGM(XXX/LIBL008CL) + */
/* SRCFILE(XXX/SOURCE) TEXT('Restore Library +*/
/* List') */
/* */
/*===================================================================*/

CMD PROMPT('Restore Library List') /*===================================================================*/

/* To compile: */
/* */
/* CRTCLPGM PGM(XXX/LIBL008CL) SRCFILE(XXX/SOURCE) + */
/* TEXT('CPP for RSTLIBL command') */
/* */
/*===================================================================*/

PGM

DCL VAR(&CMD) TYPE(*CHAR) LEN(300)
DCL VAR(&CMDLEN) TYPE(*DEC) LEN(15 5) VALUE(300)
DCL VAR(&CURLIB) TYPE(*CHAR) LEN(10)

DCL VAR(&DTAQE) TYPE(*CHAR) LEN(300)
DCL VAR(&DTAQELEN) TYPE(*DEC) LEN(5) VALUE(300)
DCL VAR(&USRLIBL) TYPE(*CHAR) LEN(275)

DCL VAR(&WAIT) TYPE(*DEC) LEN(5) VALUE(0)

MONMSG MSGID(CPF0000 MCH0000) EXEC(GOTO CMDLBL(ERROR))

/* Reject request if SAVLIBL not executed before */
CHKOBJ OBJ(QTEMP/LIBLSTACK) OBJTYPE(*DTAQ)
MONMSG MSGID(CPF9801) EXEC(DO)

SNDPGMMSG MSGID(CPF9898) MSGF(QCPFMSG) MSGDTA('RSTLIBL +
not allowed before SAVLIBL') MSGTYPE(*ESCAPE)
ENDDO

/* Restore library list */
CALL PGM(QRCVDTAQ) PARM('LIBLSTACK' 'QTEMP' +

&DTAQELEN &DTAQE &WAIT)

/* Reject request if nothing to restore */
IF COND(&DTAQE *EQ ' ') THEN(DO)

SNDPGMMSG MSGID(CPF9898) MSGF(QCPFMSG) MSGDTA('Library +
list stack is empty') MSGTYPE(*ESCAPE)
ENDDO

CHGVAR VAR(&CURLIB) VALUE(%SST(&DTAQE 1 10))
CHGVAR VAR(&USRLIBL) VALUE(%SST(&DTAQE 11 275))

CHGCURLIB CURLIB(&CURLIB)
CHGVAR VAR(&CMD) VALUE('CHGLIBL (' *BCAT &USRLIBL +

*TCAT ')')
CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)

RETURN

ERROR:

FWDPGMMSG
MONMSG MSGID(CPF0000)

ENDPGM

Figure 10: Using SAVLIBL and RSTLIBL

PGM

/* Save library list at this point */
SAVLIBL

/* Modify library list as needed */
ADDLIBLE ...

RMVLIBLE ...
CHGCURLIB ...

/* Do other tasks */

Figure 9: CL program LIBL008CL

...

CALL pgm1 /* Program may use SAVLIBL and RSTLIBL too */
...

/* Restore library list */
RSTLIBL

/* Continue processing */

ENDPGM