Register and use the Command Analyzer Retrieve exit point.

I recently received a note from Phillip M., asking about the availability of APIs to aid in his testing of CL programs. In part, he says, "The commands generate CPF, BRM, and LNT message id's. I can't duplicate hardly any of the errors that will come up and I need to test the CL thoroughly before I put it into production. I really need the MONMSG command to pick up what I throw at it."

Having had similar needs in the past--how to generate specific failure conditions for testing purposes--I can readily understand his need. And I suspect some of you reading this article feel likewise. Fortunately, there is a fairly easy way to accomplish his objective (assuming that your system is at V4R5 or later).

For demonstration purposes, here is sample program Monitor Escape, MONESCAPE, which we need to test in terms of proper handling of a CPF414E (Library device not ready) error condition when running the DONOTHING command.

Pgm                                               

Dcl        Var(&X) Type(*Char) Len(50)            

ChgVar     Var(&X) Value('A One')                 

DoNothing                                         

MonMsg     MsgID(CPF414E) Exec( +                  

             Chgvar Var(&X) +                     

               Value(&X *TCat ', and a Two'))     

ChgVar     Var(&X) +                              

             Value(&X *TCat ', and a Three')      

SndPgmMsg  Msg(&X)                                

Return                                            

EndPgm      

When the MONESCAPE program runs without receiving a CPF414E message, the output is 'A One, and a Three'. If a CPF414E is received during the running of MONESCAPE, the output is 'A One, and a Two, and a Three'.

Here's the source for the DONOTHING command:

Cmd        Prompt('Do Nothing, But Do It Well')

And the command can be created into library VINING by using CRTCMD CMD(VINING/DONOTHING) PGM(VINING/DONOTHING).

The command processing program (CPP) for the DONOTHING command is this:

Pgm    

Endpgm 

It's created into library VINING with the command CRTBNDCL PGM(VINING/DONOTHING).

Looking at the source for the DONOTHING CPP, you can see that this command will run very, very quickly. But to test the MONMSG MSGID(CPF414E) found in the MONESCAPE program, we need to send a CPF414E *ESCAPE message while the DONOTHING command is running. So how do we send the *ESCAPE message at just the right time?

In a recent column, "Understanding the CHKKILL Program," we saw how we can use the Command Analyzer Change exit point to have a user program receive control whenever a particular command is being run and, in that column, how to change the command parameters. In the current case, we have no interest in changing the DONOTHING command, but there was mention in the article of another system-provided exit point: the Command Analyzer Retrieve exit point. This exit point allows us to have an exit program receive control whenever a given command is running, which certainly sounds like something we need for our testing purposes.

Here's the source for a very simplistic exit program to send CPF414E *ESCAPE messages:

Pgm        Parm(&Parm)                                    

Dcl        Var(&Parm)     Type(*Char) Len(1)             

Dcl        Var(&User)     Type(*Char) Len(10)            

RtvJobA    User(&User)                                   

If         Cond(&User *Eq ViningTest) Then( +            

           SndPgmMsg MsgID(CPF414E) MsgF(QCPFMsg) +      

              ToPgmQ(*Same (MonEscape)) MsgType(*Escape))

EndPgm                                                   

This program, called Send Escape (SNDESCAPE), can be created into library VINING with CRTBNDCL PGM(VINING/SNDESCAPE).

The program takes one parameter, &Parm, which is passed to the program from the Command Analyzer Retrieve exit point. In this initial version of the SNDESCAPE program, we are not using any of the data found in this parameter, and we simply define the parameter as being a single-byte *Char variable. We will be making more use of this parameter, though, in a future version of SNDESCAPE.

After declaring the variable &Parm, the SNDESCAPE program declares the variable &User and then runs the Retrieve Job Attributes (RTVJOBA) command to determine the signed-on user for the job. If the user is VININGTEST, the program sends *ESCAPE message CPF414E to the program MONESCAPE, using the Send Program Message (SNDPGMMSG) command. If the user is not VININGTEST, the program simply returns.

So if we want to send the escape CPF414E message to the program MONESCAPE whenever the DONOTHING command is being run in a job initially started (signed on) by VININGTEST, all we need to do is register SNDESCAPE to the Command Analyzer exit point. Use this command to do that:

ADDEXITPGM EXITPNT(QIBM_QCA_RTV_COMMAND) FORMAT(RTVC0100) PGMNBR(1)

   PGM(VINING/SNDESCAPE) PGMDTA(*JOB 20 'DONOTHING VINING')

If you get the error message CPF3CDF (Exit program number 1 already assigned...), then change the PGMNBR parameter to another value and retry the command. Alternatively, you can use the Work with Registration Information (WRKREGINF) command to add the exit program.

One important aspect of using the ADDEXITPGM command is that the added exit program (in our case, VINING/SNDESCAPE) will now run every time any job on the system runs the DONOTHING command. For this reason, you want to determine quickly (as SNDESCAPE does by examining the signed-on user profile) if anything needs to be done in the exit program and, if not, return. You will also want to make sure the exit program doesn't have any errors, such as endless loops, long delays waiting for an object to become available, etc.

To remove the exit program, use this:

 RMVEXITPGM EXITPNT(QIBM_QCA_RTV_COMMAND) FORMAT(RTVC0100) PGMNBR(1)

Note that the PGMNBR parameter value needs to match the value used with the previous ADDEXITPGM command.

As mentioned earlier, the current SNDESCAPE program is very simplistic, but it does work when run in an appropriate environment, which means this:

•·                     The job testing the CPF414E message-handling must have been started by user VININGTEST (or at least some user profile that is known in advance), which is, I believe, a reasonable assumption for testing purposes.

•·                     Any job signed on as VININGTEST wants to test the CPF414E error-handling. Again, that seems to be a reasonable (or at least manageable) dependency.

•·                     There is a separate exit program for each command that needs to be tested, which is most likely not a reasonable assumption and/or requirement.

•·                     There is no need to test error-handling in the MONESCAPE program that is based on replacement data within the CPF414E message--most likely not a reasonable assumption.

•·                     The program MONESCAPE is the only program in the current job that runs the DONOTHING command (otherwise, the SNDPGMMSG command will fail). Again, most likely not a reasonable assumption.

In the next column, we'll address what I consider to be "unreasonable" assumptions in the SNDESCAPE exit program.

More CL Questions?              

Wondering how to accomplish a function in CL? Send your CL-related questions to me at This email address is being protected from spambots. You need JavaScript enabled to view it.. I'll try to answer your burning questions in future columns.

Bruce Vining is president and co-founder of Bruce Vining Services, LLC, a firm providing contract programming and consulting services to the System i community. He began his career in 1979 as an IBM Systems Engineer in St. Louis, Missouri, and then transferred to Rochester, Minnesota, in 1985, where he continues to reside. From 1992 until leaving IBM in 2007, Bruce was a member of the System Design Control Group responsible for OS/400 and i5/OS areas such as System APIs, Globalization, and Software Serviceability. He is also the designer of Control Language for Files (CLF).A frequent speaker and writer, Bruce can be reached at This email address is being protected from spambots. You need JavaScript enabled to view it.. 

---

MC Press books written by Bruce Vining available now on the MC Press Bookstore.

		IBM System i APIs at Work Leverage the power of APIs with this definitive resource. List Price $89.95 Now On Sale

Also Read

TechTip: Printing from a CL Program (the PRTLN Command)

TechTip: Date Arithmetic in CL Programs

TechTip: Entering Quotes in CL Variables — A Better Way?