There's probably nothing worse than having a cryptic, system-issued error message replace the entire screen of a user's display while he's trying to get his work done. Often, the error message requires a response. However, because the messages are usually difficult to interpret, the user can't determine the appropriate response. Even after a response is supplied, the message sometimes cascades into other messages.

These obtrusive, obnoxious error messages are often a result of CL programs not being written to deal with unexpected errors. And, even though a programmer can try, it is difficult to anticipate every possible error that may occur. Fortunately, IBM provided us with what is called program-level message monitoring (often referred to as global message monitoring).

There is a commonly accepted method for performing this type of monitoring, which I'll describe in the next section. It works but, as of V2R2, you can simplify the method with the use of APIs. What I'm offering you here is this simplified version bundled into a shell CL program (CLPGMSHELL, in 1) that you can use as a starting point for almost any CL program you write. It will provide you with a standard, efficient way for your programs to handle errors at the program level. I've also included some documentation features. If you already have your own standard documentation, simply remove the first section of comments from my shell.

There is a commonly accepted method for performing this type of monitoring, which I'll describe in the next section. It works but, as of V2R2, you can simplify the method with the use of APIs. What I'm offering you here is this simplified version bundled into a shell CL program (CLPGMSHELL, in Figure 1) that you can use as a starting point for almost any CL program you write. It will provide you with a standard, efficient way for your programs to handle errors at the program level. I've also included some documentation features. If you already have your own standard documentation, simply remove the first section of comments from my shell.

Global Monitoring

The key to global message monitoring is placing a Monitor Message (MONMSG) command after the last declare statement of your program. You supply a specific or generic message identifier. No matter what command in your program causes the generic or specific message ID to be issued, it will automatically be monitored. To further qualify the monitor, you can optionally specify a character string that is compared with the message data of the received message. For more information about monitoring messages in a CL program, refer to the CL Programmer's Guide (SC41-8077, CD-ROM QBKA7101).

The monitor I've defined so far traps all escape, notify and status error messages that aren't explicitly trapped at the command-level elsewhere in the program. Once trapped, the messages are normally sent back to the calling program. This is accomplished by using the EXEC parameter of the MONMSG command to cause a branch (GOTO) to a portion of your CL program that will explicitly send the messages to the caller. (GOTO is the only command that can be specified with a program-level MONMSG command.)

It is up to you to make the program-level MONMSG command monitor the messages you want to trap (CLPGMSHELL uses CPF0000 by default). You must use the ppphhhh format where "ppp" represents the licensed program (the first character is always alphabetic and can be followed by two alphanumerics), and "hhhh" represents the digits of the message ID in hexadecimal notation. Zeros in either two or all four of the rightmost positions cause generic message trapping to occur.

For example, the statement below traps any CPF21xx message (CPF2101, CPF2105, and so on) issued to your program and not monitored at the command level, and causes the program to branch to the ERRPROC tag:

 MONMSG MSGID(CPF2100) + EXEC(GOTO CMDLBL(ERRPROC)) 

At the ERRPROC label, CLPGMSHELL issues the Send Program Message (SNDPGMMSG) command to send information to the calling program. The generally accepted practice is to send all diagnostic messages that may have been issued, along with the last escape message, to the calling program's message queue. Before you can send these messages, you must first receive them. This process requires a program loop which receives and sends each diagnostic message until there are no more diagnostic messages to send. The loop is exited and the last escape message is sent as an escape message to cause the program to terminate. You can see this technique used in many of the CL programs in the QUSRTOOL library. Now for a better way.

CLPGMSHELL Highlights

By using two of the message APIs, the technique described above can be simplified. We can do away with the need to receive every message you want to send back to the caller, thus eliminating the loop. This is especially beneficial since CL doesn't directly support DO loops (you have to code GOTO tags).

Since I've already explained how global message monitoring works, I'm only going to give you an overview of how this program handles program-level messages. I will explain some of the highlights that make this program work. For more insight into the message-handling APIs, refer to the System Program- mer's Interface Reference manual (SC41-8223, CD-ROM QBKA8401) and to "More Powerful Message Subfiles" elsewhere in this issue.

The CLPGMSHELL basically has three working sections.

1. The declaration section, where the variables for the message APIs are declared.

2. The program-level monitor-one MONMSG command.

3. The error-handling section, where the messages are sent to the previous program's message queue.

The message APIs, like many other APIs, require parameter values to be expressed in binary form. In this program, I set up several required binary values by loading the hexadecimal representation of the binary value into a character variable. For example, notice the last variable declared, &STKCTR (program stack counter used by one of the APIs), where I load a binary value of 1 by using the hexadecimal representation of that value (X'00000001'). If I wanted to load a binary value of 10, I would have used hexadecimal value X'0000000A'.

The last-but most important-section is the error-handling section, where I exploit the power of two message APIs. It starts at the ERRPROC tag. The program calls the Move Program Message (QMHMOVPM) API to move all diagnostic messages to the previous program's message queue at once. No program loop has to be created to receive and send each message. The program then calls the Resend Escape Message (QMHRSNEM) API to send the last escape message to the previous program's message queue. Here again, there is no need to receive the message before we send it.

If any exception messages are issued within the error handler, they create the potential for an infinite loop. This is because the exception message will engage the program-level monitor and the program will branch to the ERRPROC tag. Since the same code that issued the exception message is executed again, the same error will be trapped again, and the program will repeat the same branch indefinitely.

To prevent this, the program sets an error flag on (logical variable &ERROR) the first time the error procedure is processed. If the error procedure is entered again, the error flag will be on and the program will branch to the ERRDONE tag. This causes the exception message to be resent via the QMHRSNEM API call.

It is possible, although unlikely, that the call could issue an exception message; therefore, I use a generic CPF0000 monitor at this statement. If this happens, an escape message CPF3CF2 is generated via the Send Program Message (SNDPGMMSG) command, which says that an error occurred while processing the API. I'm using SNDPGMMSG here instead of the API since if the program gets to here it means the API is failing.

One last thing-just in case the SNDPGMMSG fails (very, very unlikely), I use a generic monitor. If it fails, no escape message will be sent.

Starting Out on the Right Foot

With very little effort (or thought), you can include program-level message processing capabilities in your CL programs to easily and gracefully get information back to the calling program. The next time you write a CL program, start by including the CLPGMSHELL.

Richard Shaler is a senior technical editor at Midrange Computing.

Simplify CL Global Message Monitoring

Figure 1 The CLPGMSHELL

 /*==================================================================*/ /* */ /* Program name: CLPGMSHELL */ /* */ /* Purpose: To be used as a CL shell that provides generic */ /* message handling. Moves all *DIAG and *ESCAPE */ /* messages to the previous program's message queue.*/ /* */ /* Author: Joe Programmer */ /* */ /* Date created: 99/99/99 */ /* */ /* Notes: Requires mainline code */ /* */ /* */ /*==================================================================*/ /* M o d i f i c a t i o n L o g */ /* ------------------------------- */ /* */ /* Date Ini Description */ /* -------- --- ------------------------------------------------- */ /* 99/99/99 */ /* */ /*==================================================================*/ PGM PARM() /* Declare parameter variables */ /* Declare program variables */ /* Declare error processing variables */ DCL VAR(&ERRBYTES) TYPE(*CHAR) LEN(4) + VALUE(X'00000000') DCL VAR(&ERROR) TYPE(*LGL) VALUE('0') DCL VAR(&MSGKEY) TYPE(*CHAR) LEN(4) DCL VAR(&MSGTYP) TYPE(*CHAR) LEN(10) VALUE('*DIAG') DCL VAR(&MSGTYPCTR) TYPE(*CHAR) LEN(4) + VALUE(X'00000001') DCL VAR(&PGMMSGQ) TYPE(*CHAR) LEN(10) VALUE('*') DCL VAR(&STKCTR) TYPE(*CHAR) LEN(4) + VALUE(X'00000001') /* Declare file */ /* Default monitoring */ MONMSG MSGID(CPF0000) EXEC(GOTO CMDLBL(ERRPROC)) /*==================================================================*/ /* Mainline */ /*==================================================================*/ /*==================================================================*/ /* Normal end of program */ /*==================================================================*/ /* Send completion messages here */ RETURN /*==================================================================*/ /* Error processing routine */ /*==================================================================*/ ERRPROC: IF COND(&ERROR) THEN(GOTO CMDLBL(ERRDONE)) ELSE CMD(CHGVAR VAR(&ERROR) VALUE('1')) /* Move all *DIAG messages to previous program queue */ CALL PGM(QMHMOVPM) PARM(&MSGKEY &MSGTYP + &MSGTYPCTR &PGMMSGQ &STKCTR &ERRBYTES) /* Resend last *ESCAPE message */ ERRDONE: CALL PGM(QMHRSNEM) PARM(&MSGKEY &ERRBYTES) MONMSG MSGID(CPF0000) EXEC(DO) SNDPGMMSG MSGID(CPF3CF2) MSGF(QCPFMSG) + MSGDTA('QMHRSNEM') MSGTYPE(*ESCAPE) MONMSG MSGID(CPF0000) ENDDO ENDPGM /*==================================================================*/