Use pointers to process variable-length character strings.

In the previous article, "Support Variable-Length Parameters with Commands," we saw how the command processing program (CPP) of the Trim Left Characters (TRMLFTCHR) command could support character parameters of almost any arbitrary length that can be declared on a given release. Essentially, the CPP used the substring built-in, %sst, to process each byte of the input parameter while ensuring that each byte accessed was within the declared size of the input variable. Using %sst, however, introduced limitations in the CPP—namely, that the %sst built-in only works within the constraints of a declared variable: in particular, the length (LEN) declared for the character variable within the TRMLFTCHR CPP. Today, we will update the TRMLFTCHR CPP so that pointers are used to access the value of the input character parameter. Pointers, unlike %sst, are not constrained to working only with the declared length of a character variable.

There is no change to the command definition of TRMLFTCHR that we used in the previous article with CL. There are changes to the CPP, however, and these are shown below. Note that this update to the CPP does require that your system be at V5R4 or higher due to the use of CL pointer support.

Pgm        Parm(&Char_Parm)                                  

Dcl        Var(&Char_Parm)  Type(*Char) Len(5)               

  Dcl        Var(&Char_Siz)   Type(*Int) Stg(*Defined) +     

               DefVar(&Char_Parm 1)                          

  Dcl      Var(&First_Char) Type(*Char) Len(1) +             

             Stg(*Defined)    DefVar(&Char_Parm 5)           

Dcl        Var(&Char_Ptr)   Type(*Ptr)                       

Dcl        Var(&Char)       Type(*Char) Len(1) +             

             Stg(*Based)    BasPtr(&Char_Ptr)                

Dcl        Var(&CharTgtPtr) Type(*Ptr)                       

Dcl        Var(&Char_Tgt)   Type(*Char) Len(1) +             

             Stg(*Based)    BasPtr(&CharTgtPtr)              

Dcl        Var(&Char_Pos)   Type(*UInt)                       

Dcl        Var(&Char_Rem)   Type(*UInt)                              

ChgVar     Var(&Char_Ptr) Value(%addr(&First_Char))                 

ChgVar     Var(&CharTgtPtr) Value(%addr(&First_Char))               

DoFor      Var(&Char_Pos) From(1) To(&Char_Siz)                      

           If Cond(&Char *EQ '0') Then(Do)                           

              ChgVar Var(%ofs(&Char_Ptr)) Value(%ofs(&Char_Ptr) + 1) 

              Iterate                                                

              EndDo                                                  

           Else Cmd(Leave)                                           

           EndDo                                                      

If         Cond(&Char_Pos *LE &Char_Siz) Then(Do)                    

           DoFor Var(&Char_Pos) From(&Char_Pos) To(&Char_Siz)        

                 ChgVar Var(&Char_Tgt) Value(&Char)                  

                 ChgVar Var(%ofs(&CharTgtPtr)) +                     

                          Value(%ofs(&CharTgtPtr) + 1)               

                 ChgVar Var(%ofs(&Char_Ptr)) +                     

                          Value(%ofs(&Char_Ptr) + 1)               

                 EndDo                                             

           If Cond(&Char_Ptr *NE &CharTgtPtr) Then(Do)             

              ChgVar Var(&Char_Rem) +                              

                       Value(%ofs(&Char_Ptr) - %ofs(&CharTgtPtr))  

              DoFor Var(&Char_Pos) From(1) To(&Char_Rem)           

                    ChgVar Var(&Char_Tgt) Value(' ')               

                    ChgVar Var(%ofs(&CharTgtPtr)) +                

                             Value(%ofs(&CharTgtPtr) + 1)          

                    EndDo                                           

              EndDo                                                

           EndDo                                                   

Else       Cmd(Do)                                                  

           ChgVar Var(&Char_Tgt) Value('0')                        

           ChgVar Var(%ofs(&CharTgtPtr)) +               

                    Value(%ofs(&CharTgtPtr) + 1)         

           DoFor Var(&Char_Pos) From(2) To(&Char_Siz)    

                 ChgVar Var(&Char_Tgt) Value(' ')        

                 ChgVar Var(%ofs(&CharTgtPtr)) +         

                          Value(%ofs(&CharTgtPtr) + 1)   

                 EndDo                                    

           EndDo                                                                                                       

EndPgm                                                      

Changes to the CPP

The CPP could be implemented using several different approaches. The changes I've made to the CPP are attempting to maximize the similarity in style and logic to what was used in previous versions of the TRMLFTCHR CPP.

In the latest version of the CPP, the &Char_Parm parameter is defined as a character variable with a length of 5 bytes. The first 4 bytes are then redefined as the 4-byte integer &Char_Siz, representing the declared length of the CL variable specified with the VAR parameter of the TRMLFTCHR command. The fifth byte of the parameter &Char_Parm is redefined as the 1-byte character variable &First_Char. Rather than attempting to define the maximum size of the CL variable string being passed to the CPP, as was done in earlier versions of this program, the program now defines the minimum size of the CL variable string. As an aside, even this definition of the 1-byte &First_Char variable is not necessary. But I believe it may aid some in later visualizing how the program works.

Following the definition of the parameter &Char_Parm, the program defines the pointer variable &Char_Ptr and the 1-byte character variable &Char. This &Char variable is defined as being based on the &Char_Ptr pointer variable. Being STG(*BASED) means that whatever byte of storage &Char_Ptr is addressing (due to the BASPTR(&CHAR_PTR) specification when DCLing &Char), the 1-byte value located at that storage address can be accessed as CL variable &Char. Conceptually, this is similar to how the variable &Char_Pos is used in earlier program versions to identify the byte (character) of the input character string, which is currently being processed. But rather than using &Char_Pos and %sst operations such as %sst(&Char &Char_Pos 1), the &Char_Ptr variable will now be used to identify the byte of the input string being processed.

In the same manner that &Char_Ptr replaces the earlier use of &Char_Pos in identifying the 1-byte character being processed, the program also declares the variables &CharTgtPtr and &Char_Tgt to replace the earlier use of &Char_Tgt in identifying the target byte of the input character string to update when left-adjusting (moving) the input character string value.

Prior to entering the initial DOFOR loop, the CPP uses the CHGVAR command to set both the &Char_Ptr and the &CharTgtPtr pointer variables to the address of the &First_Char variable. This means that both of the based CL character variables &Char and &Char_Tgt are now referencing the first byte of the input character string (that is, the first byte of the CL variable value that was specified with the VAR keyword of the TRMLFTCHR command). The program then enters the initial DOFOR loop.

The statement "If Cond(&Char *EQ '0')", when initially entering the DOFOR, is equivalent to the "If Cond(%sst(&Char &Char_Pos 1) *EQ '0')" test in the previous version of the CPP. Both statements are testing the single byte, located at the first byte of the input character string, to the character constant of '0'. In the case of the new CPP, this is due to the &Char_Ptr pointer variable addressing the initial byte of the input character string. In the case of the previous CPP, this is due to the &Char_Pos integer variable being set to the value 1 so that the %sst operation is addressing the initial byte of the input character string. If this comparison to '0' is true, the program needs to then process (or examine) the next byte of the input character string. Using the earlier version of the CPP, this could be done by simply ITERATEing the DOFOR loop as that causes the value of &Char_Pos to be incremented by 1. With the new CPP, we need to explicitly add 1 to the pointer value of &Char_Ptr. To do this, we use the following command:

ChgVar Var(%ofs(&Char_Ptr)) Value(%ofs(&Char_Ptr) + 1)     

This CHGVAR command adds 1 to the offset value of the &Char_Ptr pointer variable. By adding 1 to the offset value of this pointer, the variable &Char (which is DCLed as based on the &Char_Ptr pointer) is now representing the next byte of the input character string. In case you're wondering, it is also possible to use the DOFOR control variable &Char_Pos to set the correct offset for the &Char_Ptr variable, but I elected not to do so in order to keep this discussion as straightforward as possible. After adding one to the pointer variable offset, the updated CPP ITERATEs the DOFOR control loop.

When the initial DOFOR loop is exited, either having found a non-zero character or having processed all characters in the input character string, the same type of processing is performed. If a non-zero character value was found, the program left-adjusts the remaining characters of the input character string and then blank pads the necessary number of trailing bytes. But rather than using %sst to implement this function, the updated CPP uses the based variables &Char and &Char_Tgt. The actual mechanics involved, incrementing the &Char_Ptr and &CharTgtPtr offset values in order to access and update the &Char and &Char_Tgt variables, respectively, are the same as when looking for leading zeros within the input character string, so we won't bother discussing this any further. For that matter, the remainder of the program uses this same pointer and based-variable support.

Creating the CPP

To compile the TRMLFTCHR CPP, use either of these commands:

CRTBNDCL PGM(TRMLFTCHR)

or

CRTCLPGM PGM(TRMLFTCHR)

If you are using the CRTBNDCL command to create an ILE program, make sure that you have the following PTFs applied to your system before creating the CPP:

V5R4 SI39398

V6R1 SI39405

V7R1 SI39407

With this most recent version of the TRMLFTCHR CPP, the command can now left-adjust any non-negative numeric value represented in character form, regardless of the declared size of the character variable. If the command can pass the CPP a character variable declared with a size of 32767 bytes, we'll handle it. If a few years down the road IBM supports a declared size of 65535 bytes, we'll handle it as long as IBM continues to pass command parameters in the same fashion as they do today. With this version of the CPP, there are no longer any maximums hardcoded in the CPP. The only size limitation is related to how large a number can fit into the 4-byte integer &Char_Siz, which is 2147483647 for a signed integer. Try the TRMLFTCHR command with some CL test programs of your own.

But what about other character values? What if, for instance, we had a character variable with the value "   ABC   " (that is three blanks, the letters ABC, and then three additional blanks) or the value "***ABC"? What would it take to have TRMLFTCHR also left-adjust and trim either leading blanks or leading asterisks so that we end up with "ABC" in both cases? The answer is "not much," and that's exactly what we will do in the next article as we further explore how to implement user commands.

Program Puzzler

Though not relevant to the discussion of handling variable-length character strings within a CPP, there are two DOFOR loops within the new TRMLFTCHR CPP that bother me. The two DOFORs I'm referring to are those related to blank-padding the input character string. One loop is run after left-adjusting any significant values found in the input character string; the second loop is related to when no significant characters are found in the input string. In previous versions of the CPP, these DOFOR loops were unnecessary as CHGVAR provided the blank-padding. Can you think of a way to eliminate the need for these DOFORs that are updating the input character string with a predetermined number of blank characters?

Some longtime readers of this column who possess excellent memories might know the answer I'm thinking of. For the rest of you, I suggest reviewing the article "Understanding the CHKKILL Program" originally published back in February of 2009. Note that the solution I have in mind only applies to an ILE-compiled TRMLFTCHR CPP. With OPM, you're pretty much stuck with the DOFORs.

The answer I have in mind can be found in next month's article.

More CL Questions?

Wondering how to accomplish a function in CL? Send your CL-related questions to me at This email address is being protected from spambots. You need JavaScript enabled to view it..

Bruce Vining is president and co-founder of Bruce Vining Services, LLC, a firm providing contract programming and consulting services to the System i community. He began his career in 1979 as an IBM Systems Engineer in St. Louis, Missouri, and then transferred to Rochester, Minnesota, in 1985, where he continues to reside. From 1992 until leaving IBM in 2007, Bruce was a member of the System Design Control Group responsible for OS/400 and i5/OS areas such as System APIs, Globalization, and Software Serviceability. He is also the designer of Control Language for Files (CLF).A frequent speaker and writer, Bruce can be reached at This email address is being protected from spambots. You need JavaScript enabled to view it.. 

---

MC Press books written by Bruce Vining available now on the MC Press Bookstore.

		IBM System i APIs at Work Leverage the power of APIs with this definitive resource. List Price $89.95 Now On Sale

Also Read

TechTip: Printing from a CL Program (the PRTLN Command)

TechTip: Date Arithmetic in CL Programs

TechTip: Entering Quotes in CL Variables — A Better Way?